PDA

View Full Version : Solved: Removing Noncontiguous DropDown Arrows



Opv
07-14-2010, 11:10 AM
Is there any way to simplify this script. I tried the loop that is commented out and it indeed removes the dropdown arrows but it doesn't apply the previously defined filters.


Sub createKiddingView()

Call getRows

Sheets("(History)").Activate

Application.EnableEvents = False
Application.screenUpdating = False

ActiveWorkbook.CustomViews("Kidding").Show

''''' FILTER TO DISPLAY ONLY DOES '''''
With Sheets("(History)")
.AutoFilterMode = False
.FilterMode = False
.Range("I2:AB" & currentRows).Select
Selection.AutoFilter
Selection.AutoFilter field:=1, Criteria1:="Doe", visibledropdown:=False
Selection.AutoFilter field:=2, Criteria1:=">=1", visibledropdown:=False
Selection.AutoFilter field:=3, visibledropdown:=False
Selection.AutoFilter field:=4, visibledropdown:=False
Selection.AutoFilter field:=5, visibledropdown:=False
Selection.AutoFilter field:=6, visibledropdown:=False
Selection.AutoFilter field:=7, visibledropdown:=False
Selection.AutoFilter field:=8, visibledropdown:=False
Selection.AutoFilter field:=9, visibledropdown:=False
Selection.AutoFilter field:=10, visibledropdown:=False
Selection.AutoFilter field:=11, visibledropdown:=False
Selection.AutoFilter field:=12, visibledropdown:=False
Selection.AutoFilter field:=13, visibledropdown:=False
Selection.AutoFilter field:=14, visibledropdown:=False
Selection.AutoFilter field:=15, visibledropdown:=False
Selection.AutoFilter field:=16, visibledropdown:=False
Selection.AutoFilter field:=17, visibledropdown:=False
Selection.AutoFilter field:=18, visibledropdown:=False
Selection.AutoFilter field:=19, visibledropdown:=False
Selection.AutoFilter field:=20, Criteria1:="=1", visibledropdown:=False

' With Range("I2:AB2")
' Dim i As Integer
' For i = 1 To 20
' .AutoFilter field:=i, VisibleDropDown:=False
' Next i
' End With


End With

Application.EnableEvents = True
Application.screenUpdating = True

End Sub

p45cal
07-14-2010, 03:28 PM
try:
Sub createKiddingView()
Dim i As Integer
Call getRows
Sheets("(History)").Activate
Application.EnableEvents = False
Application.ScreenUpdating = False
ActiveWorkbook.CustomViews("Kidding").Show
''''' FILTER TO DISPLAY ONLY DOES '''''
With Sheets("(History)")
.AutoFilterMode = False
.FilterMode = False
With .Range("I2:AB" & currentRows)
.AutoFilter
.AutoFilter field:=1, Criteria1:="Doe", VisibleDropDown:=False
.AutoFilter field:=2, Criteria1:=">=1", VisibleDropDown:=False
.AutoFilter field:=20, Criteria1:="=1", VisibleDropDown:=False
For i = 3 To 19
.AutoFilter field:=i, VisibleDropDown:=False
Next i
End With
End With
Application.EnableEvents = True
Application.ScreenUpdating = True
End Sub

Opv
07-14-2010, 04:04 PM
Thanks. That seems to do the trick. I appreciate the help.

Opv