Solved: Return value for a false statment

[gimli]

Hey all,

Beating my head in trying to return a value for this statement if "false"


=IF(AND($F$8=6,AL21<0.18,BM21="YES"),"T",IF(BM21="YES",IF(OR($F$8=55,$F$8=54,$F$8=56,$F$8=64,$F$8=61,$F$8=65,$F$8=62,$F$8=67,$F$8 =70,$F$8="X",$F$8=69,$F$8=615),"OK")))

Thought adding this would work but doesnt..see red. Trying to return "nope" instead of false.

=IF(AND($F$8=6,AL21<0.18,BM21="YES"),"T",IF(BM21="YES",IF(OR($F$8=55,$F$8=54,$F$8=56,$F$8=64,$F$8=61,$F$8=65,$F$8=62,$F$8=67,$F$8 =70,$F$8="X",$F$8=69,$F$8=615),"OK","NOPE")))

Thanks much

[nepotist]

Did you try to use the evaluate formula option to see what is happening?

[Bob Phillips]

Try this

=IF(AND($F$8=6,AL21<0.18,BM21="YES"),"T",
IF(AND(BM21="YES",OR($F$8=55,$F$8=54,$F$8=56,$F$8=64,$F$8=61,$F$8=65,$F$8=62,$F$8=67,$F$8=70 ,$F$8="X",$F$8=69, $F$8=615)),"OK","NOPE"))

[austenr]

:bug:

[gimli]

Yes..that worked..but now im looking at the results and my logic is screwed up...grrr

will work on it more and post tommorow if my logic is still messed up..:banghead:

[gimli]

Ok...i attached a file with what im trying to do with the formula that wont work....

any help would be great..

thanks

[Bob Phillips]

Try



=IF(AND(C5="A",C8<=0.18,C11="YES"),"BAD",
IF(OR(
AND(C5="A",C8>0.18,C11="YES"),
AND(C11="YES",OR(C5="A",C5="B",C5="C")),
AND(C11="NO",C5<>"A",C5<>"B",C5<>"C")),"OK","NO"))

[gimli]

XID,

that work based on what I told you...

this would work for me if condition 4 was this

Condition 4- if C11= "NO" OR "YES" and C5 <> A , B OR C want to return a value of OK

Instead of

Condition 4- if C11= "NO" and C5 <> A , B OR C want to return a value of OK

[Bob Phillips]

=IF(AND(C5="A",C8<=0.18,C11="YES"),"BAD",
IF(OR(
AND(C5="A",C8>0.18,C11="YES"),
AND(C11="YES",OR(C5="A",C5="B",C5="C")),
AND(OR(C11="NO",C11="YES"),C5<>"A",C5<>"B",C5<>"C")),"OK","NO"))

[gimli]

THANKS!!

:bow: