Solved: How to print a doc using absolute page numbers?

[thushan]

Is there any way to print a document using absolute page number?
For example let's say my doc has 10 pages. The absolute 6th page is the 2nd page of section 3 (p2s3). In the print dialog if I give p2s3 it prints the correct page. Similarly is there a syntax to give the absolute page number in the print dialog? (what I want is something like: (some symbol)6 to be given in the print dialog and to print the absolute 6th page. )

Thank you for any information.

Best regards,
Thushan

[fumei]

This is coming from another post. In that one you mention you have a way to determine "absolute" page number.

Please post how you do that. Thanks.

The reason I ask, is that if you can do that, then what is your problem? Print that page. As I mentioned in the other post, there is no absolute page in Word.


In the print dialog if I give p2s3 it prints the correct page.
That is because you told it which page to print.


Similarly is there a syntax to give the absolute page number in the print dialog? (what I want is something like: (some symbol)6 to be given in the print dialog and to print the absolute 6th page. )
Is there a symbol...yeah, in your case it is "p2s3". There is NO absolute page number in Word. There is the current page (which can absolutely be printed directly), and there are calculated pages. What are you trying to do? precisely. WHY do you need to use an "absolute" page number? HOW do you know what that number is? If you are looking at the screen with the cursor on that page...print THAT page. Please explain precisely what your requirements are.

But there is no absolute page number in Word. That is why Word always repaginates when it prints a document. It calculates the page numbers.

[thushan]

Thanks for the reply Gerry.
Sorry if I sound stubborn, but although every body is keep on telling me there's no such thing as "absolute" page numbers in word, I keep on seeing that number in the bottom left hand corner.
(This sounds like a conversation I used to have with my father when I was small. "There's no such thing. Then what's that?. That's nothing. :) But I have a feeling that I'll understand you all were right... when I grow up... ;))

The thing is, we cannot deny the fact that the absolute page number is there in the status bar in the bottom left hand corner of the Word window. The status bar shows something like "Page 2 Sec 7 10/25". Here what I refer by "absolute" page number is number 10. And I think we can refer p2s7 as the absolute "address" of the page (just to avoid confusion).

So, I think, Word DOES recognize the absolute page number in a way. And what I want to know is, is there any way we can tell word to print a page (or a range of pages) using absolute page numbers?

I'll start a new post titled "How to avoid printing blank pages?" to describe my real problem.

Found some new info:
Even the Go To dialog doesn't recognise simple numbers. For example if you give 4 in that dialog, it'll go to a page 4 of some section. Not to the absolute page 4.
But I found a solution to this. Using the Go To dialog you can use "p4" format to go to absolute page 4.
But if you try to print it using "p4" it prints some pages. The logic it uses to select those pages are beyond me... :(

Thank you.

Best regards,
Thushan

[fumei]

Be as stubborn as you like....Word can cause that in everyone. The numbers at the bottom are calculated, and there is nothing you can do about it, no matter how stubborn you get.

"Page 2 Sec 7 10/25". Here what I refer by "absolute" page number is number 10."

You can refer to it as absolute for as long as the cows won't come home....but it is not. Word calculates it. It does NOT, repeat it does NOT store an absolute page number. Word works on an Object Model, and the Object Model does NOT have a absolute page number. When you move the Selection (or cursor) to a different page...yes, that number changes to what appears to be an "absolute" page number.

However, what Word in FACT does is:

Sub ByRange()
Dim oRange As Word.Range
Dim var
Dim i As Integer
Dim TotalPages As Integer
On Error Resume Next
If ActiveDocument.Sections.Count > 1 Then
TotalPages = ActiveDocument.Sections(1).Range. _
Information(wdActiveEndPageNumber)
For var = 2 To ActiveDocument.Sections.Count
' set range object for current section
' pick up the page number of the last page of this section
Set oRange = ActiveDocument.Sections(var).Range
i = oRange.Sections(1).Range.Information(wdActiveEndPageNumber)
Set oRange = Nothing
TotalPages = TotalPages + (i - TotalPages)
Next
Else
TotalPages = ActiveDocument.Sections(1).Range. _
Information(wdActiveEndPageNumber)
End If
MsgBox Selection.Range.Information(wdActiveEndPageNumber) & " / " & TotalPages
End Sub

Run this through a document, moving the selection to various pages. It will display the "10/25", or "17/25" - whatever. as you can see it CALCULATES, by Section, Section by Section, the pages in THAT Section.

Page Numbers are properties of SECTION, not the Document. The document has NO pages numbers. The Section object does, and they are calculated.

Lets take another example.

1. make a document with TWO sections.
2. make the first section have four "absolute" pages..make it easy - use hard page breaks (but not section breaks).
Status line = Page 4 Sec 1 4/4 ....right?
3. make a section break next page.
Status line = Page 5 Sec 2 5/5
4. make the new section (#2) start page numbering at 16.
Status line = Page 16 Sec 2 5/5
Now come the kicker.

5. type in =rand(50, 3) and press enter. This will type in a big whack of text. Before you press Enter keep an eye on the little "book" icon on the status line. It will animate, flipping pages. This is Word recalculating / repaginating.
Status line = Page 18 Sec 2 7/7

While you can turn off repagination while editing, you can NOT turn off repagination during any print job....because Word needs to do so, to figure out the page numbers...BECAUSE there are NO absolute pages numbers within the Word Object Model.

Those status line numbers are calculated, not retrieved from a stored property.

Sorry. Be stubborn, it helps quite often to get one through a problem. And if you actually specified what your problem IS, there may quite likely be a reasonable solution. But....you need to relook the problem. You can not use absolute numbers for print.

In the above example, you have a document with:

Page 1 "Absolute" 1
Page 2 "Absolute" 2
Page 3 "Absolute" 3
Page 4 "Absolute" 4
Page 16 "Absolute" 5
Page 17 "Absolute" 6
Page 18 "Absolute" 7

Try printing Page 9......

I am glad you are starting another post regrading the real issue, the real problem. If what you want to is NOT print blank pages, then deal with that.

[MOS MASTER]

That's what I call a explanation!!!

Very nice reading material Gerry! :clap:

[fumei]

While some may find my obsession with the object model....uh, obsessive, I think it is the most efficient way to figure out what the heck is going on. The Word object model can be bizarre, really strangely beautiful, and sometime just silly and dumb. However, it is what makes Word tick.

Oh, and sometimes it cheats.

[MOS MASTER]

While some may find my obsession with the object model....uh, obsessive, I think it is the most efficient way to figure out what the heck is going on. The Word object model can be bizarre, really strangely beautiful, and sometime just silly and dumb. However, it is what makes Word tick.

Oh, and sometimes it cheats.

Sure poetry!..and yes you're a bit obsessive! :tease: (look whose talking!)

[thushan]

Thanks fumei for a very enlightneing description of the problem. :)
Ok, so word calculates the pages. Fine. So, it uses those 'calculated' numbers when you use the p8 format in Go To dialog (Ctrl + g) to go the correct 'absolute' page number. And it also uses the 'calculated' page numbering system to go to an absolute page when you use something like (and here you don't even have to use p8 format you can just say 8):
Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Name:=Str(8)

So, why can't it use this calcuated page numbering system when printing?
A Word Bug? Or we don't know how to do it?

Thanks again for your help.
/ Thushan

[MOS MASTER]

Hi, :yes

I'm still not getting how you see that print job.

But let's say for instance you'd wanted to print pages: 1, 3 and 5 to 7 you could then use something like: (From recorder)
Application.PrintOut FileName:="", Range:=wdPrintRangeOfPages, Item:= _
wdPrintDocumentContent, Copies:=1, Pages:="1,3,5-7", PageType:= _
wdPrintAllPages, Collate:=True, Background:=True, PrintToFile:=False, _
PrintZoomColumn:=0, PrintZoomRow:=0, PrintZoomPaperWidth:=0, _
PrintZoomPaperHeight:=0


Probably not what you're looking for but I don't get the question yet so be patient. :whistle:

[xCav8r]

Fight the Word Powa, Thushan!

wdGoToAbsolute

I'm loving it! :love

[Steiner]

Here's something I just cooked up, it should select absolute pages from - to and then print it out, I haven't tested it thouroughly, but it seems to work:



Sub PrintAbsolute(iFrom As Integer, iTo As Integer)
Dim Rng As Range, i As Integer, iMaxPages As Integer, lStart As Long, lEnd As Long

iMaxPages = ActiveDocument.ComputeStatistics(wdStatisticPages)
If iFrom > iMaxPages Or iTo > iMaxPages Then
MsgBox "Nope"
Exit Sub
End If

Selection.GoTo wdGoToPage, wdGoToAbsolute, iFrom
lStart = Selection.Start

If iTo = iMaxPages Then
lEnd = ActiveDocument.Range.End
Else
Selection.GoTo wdGoToPage, wdGoToAbsolute, iTo + 1
lEnd = Selection.Start - 1
End If

ActiveDocument.Range(lStart, lEnd).Select
'ActiveDocument.PrintOut range:=wdPrintSelection
End Sub


Daniel

[fumei]

Steiner - nice code....but

wdGoToAbsolute =if you parse this...wd - GoTo - Absolute

Word Calculate Absolute.

It is a method to move the Selection.

In the code above, this is STILL a calculation. it is NOT a return of a property. the object does NOT have an absolute page number, it STILL calculates things ByRef - so to speak. It is not ByVal - so to speak.

And if you carefully go through my pseudo code that Word uses to find out "absolute", you can infer that what Word actually does, is behind the scenes moves the selection to each page and calculates where it is.

OK - huge kudos for someone to find a PROPERTY that can return the absolute number of a page:

1. without moving anything - no GoTo, no MoveEnd etc etc
2. without calculating anything.

Something like: Msgbox page.AbsoluteNumber. Then show me a simple return instruction, like that, with NO movement. In other words, say the Selection is on page 1 of a 6 page document, but there is a page numbering change on a Section. There are only 6 "absolute" pages", but the page numbering goes:

Page 1
Page 2
Page 34
Page 35
Page 36
Page 37

Show me a simple return, a property that returns the fact that Page 35 is "really" the "absolute" page number 4.

Show me. Show me. I would love to be wrong in this case.

From Help:

The PageNumber objects represents a page number in a header or footer. The PageNumber object is a member of the PageNumbers collection. The PageNumbers collection includes all the page numbers in a single header or footer.

The page Number is part pf header/footer, part of Section. Each Section is "independent", and any information about other Sections have to be examined (calculated).

Again, I am quite willing to be wrong.

Find and code me a property that can return absolute page number. I will gracefully bow.

[fumei]

OK - hold on you people you can do so!

YES, it can be done by writing a class module, and including the calculated "absolute" page number as a property of an object. That object would most likely be a re-creation of a header/footer object.

This, I suspect, is in fact going on somewhere in Word. However, this property is, apparently not exposed. If it is, like I said, huge kudos from me. I can't find it.

[TonyJollans]

Hi Gerry,

Selection.Information(wdActiveEndPageNumber)

[TonyJollans]

Everybody else,

This gives you the 'absolute' page number, but it isn't of any real use for the task at hand.

[fumei]

Sorry Tony, you can say it gives the "absolute" page number...but you are missing a very important point. It gives the "absolute" page number of the page the Selection is on. And ONLY the page the Selection is on.

As the point is to be able to have, or to get, the "absolute" page number of A page , ANY page, - that is, the "absolute" page number of Page "X"....I stand by my challenge.

As I stated all along, YES, you can get an "absolute" page number, but you have to calculate every page...which is what Word precisely does when it repaginates.

There is NO absolute page number. And again, I would be happy to be wrong, if someone can show a property under the conditions given. To repeat, they are:

1. no movement, that is, no Selection going page to page - which, Tony, you would have to do to find the "absolute" page number of a page, say 6 pages away from where the Selection is. Selection.Information(wdActiveEndPageNumber) is NOT going to give you the absolute page number of say a page 6 pages farther down the document from where the Selection is...now is it?

2. No other calculation. In other words, no code procedures to do the same calculations. I posted some code to it; Steiner posted some code to do, but the end result is the same. There is NO absolute page number associated with any individual page. Even Selection.Information uses a method.

[TonyJollans]

Well, Gerry, as you know there isn't really any such thing as a page proper in Word, but if you can specify what it is you want the absolute page of, the information property of the Range will give it to you without movement, for example

ActiveDocument.Tables(17).Range.Information(wdActiveEndPageNumber)

or

ActiveDocument.Sections(3).Range.Information(wdActiveEndPageNumber)

It is the page number of the end of the range so the code would be slightly more complex to, say, collapse the Range to get the start page - but still possible.

I don't know how to specify "the page 6 pages farther down than something" but I suppose one could just add 6 to the page of the "something" if that could be specified.

However, as I said, it isn't any real use as it can't be used for anything. AFAIK there is no property or method (apart from GoTo) which takes an absolute page number as an argument.

[fumei]

Which what I have been saying. There is no parameter to pass an absolute page number.

As the ORIGINAL post asked:

is there a syntax to give the absolute page number in the print dialog? (what I want is something like: (some symbol)6 to be given in the print dialog and to print the absolute 6th page

I think, I hope, we can close this one down and state, again, - NO there is not. The reason there is no property or method that takes absolute as a parameter, is because there IS no property.

Finally, people, Tony actually hits the nail on the head with the comment

there isn't really any such thing as a page proper in Word

This is what causes a lot of these misconceptions.

There is no "page" in Word. Each page is determined by a process, it does not exists as a thing, an object proper.

There are no "words" in Word either. There is, in fact, no word object in the Word Object Model. There is a Words collection, and there an individual Item of that collection.

Open a new document.
Do a Word Count (Tools > Word Count). Count = 0
Do a Word count by code:
ActiveDocument.Words.Count = 1

Type a word ("hello")
Do a Word Count by menu: (Tools > Word Count). Count = 1
Do a Word count by code:
ActiveDocument.Words.Count = 2
ActiveDocument.Range.ComputeStatistics(wdStatisticWords) = 1
ActiveDocument.Range.Words.Count = 2


Make a new document. Type a word, a comma, a space, and another word: "hello, hello"

Do a Word Count by menu: (Tools > Word Count). Count = 2
Do a Word count by code:
ActiveDocument.Words.Count = 4.
ActiveDocument.Range.ComputeStatistics(wdStatisticWords) = 2
ActiveDocument.Range.Words.Count = 4

Same things as pages...there are no "word" objects in Word. "Words" are, in fact, calculated Range objects. The .ComputeStatistics method does NOT include punctuation and paragraph marks, but the ENUM of Word.Count DOES include punctuation and paragraph marks.

This is why ActiveDocument.Words.Count can never, EVER, = 0. Even a blank Word document has a count of 1 "word".

[Steiner]

Hi fumei,
my code wasn't there to prove you wrong or anything, it simply should address that problem

: Is there any way to print a document using absolute page number?

I know that there is no property for an absolute page number and Word only calculates it, but: How does it calculate it? And why aren't we able to reproduce that calculation?

Daniel

[fumei]

Oh sorry Daniel, I did not want to give the intention I thought you were trying to prove anything. In fact I believe I complimented you on the code.

And actually, I also pointed out that the code I posted, as well as the code you posted, DOES reproduce the calculation to a large degree.

How does it calculate it? I believe it does it more like my code, but I could be wrong. However, that is my second bet. My first bet is that Word passes out the Section parameters to a private routine in some DLL. Private in that it uses CPU cycles directly, without API. Private, in that we do not have access to it.

I don't know for sure, but Word does repaginate quicker than I expect.

[Steiner]

Then I misunderstood:bug: you, seems to happen to me quite often.

Anyway, I still think our examples don't really reproduce the calculation but force Word to use it's own as far as we can access it. And yes, you're right, it is indeed quicker than expected.

Daniel

[fumei]

Suspiciously quicker. I have tested, doing a explicit repagination procedure via VBA. Timed it. Timed a internal repagination. The repagination procedure Word uses is 50% faster than what I can do with VBA.l
In any case, while it is possible to derive a procedure that can pass a paramater that "looks' like an absolute page, there is NO function available directly in Word that is user accessible.

In other words, you could build a procedure that could take an input...say you want to print the "absolute' page 6 - it would that input, calculate what "page" it is considered to be, then print that one. But there is, again, NO absolute page number you can use directly as a parameter.

[geekgirlau]

Thushan, is that what you're after? A macro that allows you to enter "6" as the page number you want to print, that actually calculates where that page exists and instructs Word to print "p2s3"?

[fumei]

Hi geekgirlau. I believe that is the case. Which is not all that difficult. I have already written the code to do so.

The issue really is:

1. If you have the Selection on the page...then just print the page.

2. If you do NOT have the Selection on the page...how do you know it IS page 6 - or rather, the sixth page? The status line will not tell you that. Yes there is code that can calculate the printable page number of a given "absolute" page, and print it. In this case, take a "6" and make it into "p2s3". Just keep adding the number of pages per section until you reach the given number...although it is a little trickier than that.

[fumei]

Darn cats.....

The reason it is a little tricky is you have to check, for each section, to see if there ANOTHER Section after it.
Sub PageCount()
MsgBox ActiveDocument.Sections(1).Range.ComputeStatistics(wdStatisticPages)
End Sub
computes the number of pages for Section 1, right?

A) a blank new document. Message = 1 - there is one page
B) add a page break. Message = 2 - there are two pages
C) add a Section break Next Page. Looking at the document there are 2 pages in Section 1, 1 page in Section 2. HOWEVER, Message = 3. The computed number of pages for Section 1 includes the next page.

If a section has a section following, then the computed stat must be reduced by 1. If it does not, then the computed stat is correct. So you need to check the current section index number is less than the total section count.

[thushan]

Hi all,
Thank you all for your help.
And sorry about the delayed reply. Had to get some stuff tidied up.
I finally managed to write a macro that prints only non blank pages.
It uses pNsN format and ranges to print.
I am posting the macro here with.

Thank you again,
Thushan


' Copyright 2005 Standard Solutions Inc - All Rights Reserved
' Author: Thushan Abeysekera
' Date: 2005/08/31
' Description: PrintGoodPages macro prints only non blank pages.
Public Sub PrintGoodPages()
Dim docType
Dim currentPageNo As Long, currentLineNo As Long
Dim sRelativePage As String, sSection As String, sCurrentPage As String
Dim sSectionsNPages As String, sTempSectionsNPages As String, testAsc As String
Dim sStartOfRange As String, sEndOfRange As String
Dim bInclude As Boolean, bAbnormalNextPage As Boolean, bStartOfRange As Boolean
Dim Pgs As Long, i As Long, j As Long, k As Long
Dim sSectionsNPagesArr(1 To 10) As String
docType = ActiveWindow.View.Type
currentPageNo = Selection.Information(wdActiveEndPageNumber)
currentLineNo = Selection.Information(wdFirstCharacterLineNumber)
ActiveWindow.View.Type = wdPrintView
sSectionsNPages = ""
sSection = ""
sRelativePage = ""
sCurrentPage = ""
sStartOfRange = ""
sEndOfRange = ""
bInclude = False
bAbnormalNextPage = False
bStartOfRange = True
i = 0
j = 1
k = 1
Pgs = ActiveDocument.ComputeStatistics(wdStatisticPages, True)
For i = 1 To Pgs
Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Name:=Str(i)
' Check whether it has actually gone to page i http://vbaexpress.com/forum/images/smilies/001.gif
If Selection.Information(wdActiveEndPageNumber) <> i Then
j = 1
' Go down 100 lines and see whether you can go to the next page
Do Until j = 100 Or Selection.Information(wdActiveEndPageNumber) = i
Selection.MoveDown Unit:=wdLine, Count:=1
j = j + 1
Loop
'Even after going down 100 lines, if you can't go to the next page, show an warning message.
If j = 100 Then
If MsgBox("There's something wrong with this document that PrintGoodPages macro cannot recognise. If continued unexpected results may occur. Do you want to continue?" _
, vbYesNo, "Abnormal Page Break") = vbNo Then
Exit Sub
End If
End If
End If
sSection = Trim(Str(Selection.Information(wdActiveEndSectionNumber)))
sRelativePage = Trim(Str(Selection.Information(wdActiveEndAdjustedPageNumber)))
' Get the current page in pNsN format.
sCurrentPage = "p" + sRelativePage + "s" + sSection
testAsc = Asc(Selection.Characters.First)
bInclude = False

Do
' Check for the page break
If testAsc = 12 Then
' But, since ascii 12 is also used as section break,
' make sure it's a page break by going one char right.
Selection.MoveRight Unit:=wdCharacter, Count:=1
If Selection.Information(wdActiveEndPageNumber) = i Then
testAsc = Asc(Selection.Characters.First)
Else
Exit Do
End If
End If
' Check for carriage return(13), space(88), etc. (If only these are in a page,
' it's still considered as a blank page.
If testAsc = 13 Or testAsc = 88 Or testAsc = 32 Or testAsc = 21 Then
If Selection.Next(Unit:=wdCharacter, Count:=1) Is Nothing Then
Exit Do
Else
Selection.Next(Unit:=wdCharacter, Count:=1).Select
testAsc = Asc(Selection.Characters.First)
End If
Else
bInclude = True
Exit Do
End If
Loop
If bInclude Then
If bStartOfRange Then
sStartOfRange = sCurrentPage
sEndOfRange = sCurrentPage
bStartOfRange = False
Else
sEndOfRange = sCurrentPage
End If
Else
' Following is the print range generation logic.
If Not bStartOfRange Then
bStartOfRange = True
sTempSectionsNPages = sSectionsNPages
If sSectionsNPages = "" Then
If sStartOfRange = sEndOfRange Then
sSectionsNPages = sStartOfRange
Else
sSectionsNPages = sStartOfRange + "-" + sEndOfRange
End If
Else
If sStartOfRange = sEndOfRange Then
sSectionsNPages = sSectionsNPages + "," + sStartOfRange
Else
sSectionsNPages = sSectionsNPages + "," + sStartOfRange + "-" + sEndOfRange
End If
End If
' Print method can only accept a string less than 256 chars.
' If it's more than 256, printing will be done in steps.
If Len(sSectionsNPages) > 255 Then
sSectionsNPagesArr(k) = sTempSectionsNPages
k = k + 1
If sStartOfRange = sEndOfRange Then
sSectionsNPages = sStartOfRange
Else
sSectionsNPages = sStartOfRange + "-" + sEndOfRange
End If
End If
End If
End If
Next i
' Finalizing print range generation.
If Not bStartOfRange Then
bStartOfRange = True
If sSectionsNPages = "" Then
If sStartOfRange = sEndOfRange Then
sSectionsNPages = sStartOfRange
Else
sSectionsNPages = sStartOfRange + "-" + sEndOfRange
End If
Else
If sStartOfRange = sEndOfRange Then
sSectionsNPages = sSectionsNPages + "," + sStartOfRange
Else
sSectionsNPages = sSectionsNPages + "," + sStartOfRange + "-" + sEndOfRange
End If
End If
End If
sSectionsNPagesArr(k) = sSectionsNPages
For i = 1 To k
If MsgBox("Pages to print are " + sSectionsNPagesArr(i) + ". Do you want to print them?" _
, vbOKCancel, "Confirm Printing Step " + Str(i) + " of " + Str(k)) = vbOK Then
Application.PrintOut FileName:="", Range:=wdPrintRangeOfPages, Item:= _
wdPrintDocumentContent, Copies:=1, Pages:=sSectionsNPagesArr(i), PageType:= _
wdPrintAllPages, ManualDuplexPrint:=False, Collate:=True, Background:= _
True, PrintToFile:=False, PrintZoomColumn:=0, PrintZoomRow:=0, _
PrintZoomPaperWidth:=0, PrintZoomPaperHeight:=0
End If
Next i
ActiveWindow.View.Type = docType
Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=currentPageNo
Selection.GoTo What:=wdGoToLine, Which:=wdGoToRelative, Count:=currentLineNo
End Sub

[MOS MASTER]

Hi, :yes

Glad to see you've found a workable sollution! :thumb