How to Toggle All Checkboxes in a VBA Userform in Word

[johndavidson]

I have a userform with multiple checkboxes. It would be useful to have a "toggle checkboxes" cmd button, but is there an easy way to loop through all the checkboxes, toggling their values, without having to code each checkbox by name? The names of them all begin with chk*, otherwise the checkbox names are unique strings. A couple of them are locked, so their values would need to remain the same, but they could be unlocked at the start and set explicitly at the end.

Thanks

John Davidson

[mrojas]

Here's one way of doing it.


' Clear All Form Controls (using name) Dim ctl As Object
For Each ctl In Me.Controls
If Left(ctl.Name, 3) = "chk" Then
ctl.Value = False
ElseIf Left(ctl.Name, 3) = "txt" Then
ctl.Text = ""
ElseIf Left(ctl.Name, 3) = "cbo" Then
ctl.Text = ""
ctl.Clear
End If
Next
:yes

[macropod]

Perhaps:

For Each ctl In Me.Controls
With ctl
If .Name Like "chk*" Then
.Value = False
Else
Select Case .Name
Case "somename", "anothername"
.Value = False
Case Else
End Select
End If
End With
Next

[johndavidson]

Thanks to you both. For the sake of my education, I tried both, and both work just fine.

[gmaxey]

Another perhaps more universal method (the checkbox could be named anything):


Private Sub CommandButton1_Click()
Dim oCtr As Control
For Each oCtr In Me.Controls
If TypeName(oCtr) = "CheckBox" Then
oCtr.Value = Not oCtr.Value
End If
Next
End Sub

[johndavidson]

Thanks Greg. That works a treat as well, and the code is even tighter! How can one ever learn all the possible VBA-Word syntax? Especially as very much a part-timer.

[gmaxey]

IMHO, full or part timer, one can't.

[macropod]

Another perhaps more universal method (the checkbox could be named anything)
But you still need to either avoid processing the 'locked' checkboxes, or re-set them. Perhaps change:
oCtr.Value = Not oCtr.Value
to:
If oCtr.Locked = False Then oCtr.Value = Not oCtr.Value