Footnote page numbers

Sorry for the delay, for some reason I wasn't notified by email that there were new posts. Thank you all for your help, it is muchly appreciated.

Quote:

---

Originally Posted by Frosty

can you post a sample doc, MacroShadow? I don't even know how your set up is... this is back to your custom footnotes with linked textboxes, right?

---

No, this has nothing to do with the linked text boxes, now I'm dealing with Word's standard footnotes. Sample doc attached.

Quote:

---

Originally Posted by gmaxey

That is not a condition in your original post. It will help if you fully define the scope of what you are after.

---

Actually, in my original post I asked for a way to determine if the text flows over to the next page.

Quote:

---

Originally Posted by gmaxey

This will probably work for 2 columns, but not for 1 or 3:

Code:

---

Sub Test()
    MsgBox ScratchMacro(1)
End Sub

Function ScratchMacro(lngIndex) As String
    Dim oPage As Page
    Dim oRect As Rectangle
    Dim oRect2 As Rectangle
    Dim oRng As Word.Range
    Dim oRng2 As Word.Range
    Dim oRngFN As Word.Range
    Set oRngFN = ActiveDocument.Footnotes(lngIndex).Range
    Set oPage = ActiveDocument.ActiveWindow.Panes(1).Pages(ActiveDocument.Footnotes(lngIndex).Range.Information(3))
    Set oRect = oPage.Rectangles(4) '1 is main text column 1, 2 is main text column 2, 3 is the col 1separator
    '4 is col1 footnotes, 5 is col2 separator, 6 is col 2 footnotes.
    Set oRect2 = oPage.Rectangles(6)
    'not sure this would always be the case
    Set oRng = oRngFN.Duplicate
    Set oRng2 = oRngFN.Duplicate
    oRng.Collapse wdCollapseStart
    oRng2.Collapse wdCollapseEnd
    If oRng.InRange(oRect.Range) And oRng2.InRange(oRect2.Range) Then
          ScratchMacro = "Yes, the FN is on same page"
    Else
          ScratchMacro = "No, the FN spans multiple pages."
    End If
End Function

---

---

It returns "No, the FN spans multiple pages." for all footnotes, besides a couple when I got a runtime error 5941 :The requested member of the collection doesn't exist.

Quote:

---

Originally Posted by gmaxey

It will also help if you post what you've tried. This way people can spend their time trying to help you with what you've tried rather than spend it redoing what you, after the fact, inform us that you have already done.

---

You're right, I'm sorry.

Attached you will all find a sample doc.

So it seems like the rectangles approach needs more info since the .Pages(1) isn't enough to identify the actual page the footnote is on. And the other methodology seems slow to me, although it does work (footnote 16 in your attachment is split across two pages, and it is returned correctly).

So... what problem are you trying to solve, at this point? Your response was to earlier posts, but your attachment incorporates the adjustments made in later posts.

Is this solved for you, or no?

Frosty and Greg and anyone else who can lend a helping hand,

Frosty, Your latest function does work although it is quite slow.

I'm hoping Greg will come up with a faster working alternative.

In the meantime I cooked up a procedure that seems to work, the trouble is if I turn it into a function it no longer provides the correct result.

This works:

Code:

---

  Sub Test()
      Dim intPage, ingRec As Integer
      Dim strWholeFootnote, strPartFootnote, strRecTxt As String
      Dim blnFlows As Boolean
      intPage = Selection.Information(3)
      ingRec = ActiveDocument.ActiveWindow.Panes(1).Pages(intPage).Rectangles.Count
      strRecTxt = ActiveDocument.ActiveWindow.Panes(1).Pages(intPage).Rectangles(ingRec).Range.Text
      strWholeFootnote = Len(Selection.Footnotes(1).Range.Text)
      strPartFootnote = Len(Mid(strRecTxt, InStrRev(strRecTxt, Chr(2)) + 1))
      If strWholeFootnote > strPartFootnote And InStr(strRecTxt, Chr(2)) = 0 Then
            blnFlows = False
      ElseIf strWholeFootnote <= strPartFootnote Then
          blnFlows = False
      Else
            blnFlows = True
      End If
    MsgBox blnFlows
End Sub

---

This doesn’t:

Code:

---

  Function fIsSplit(Optional iFootnote As Integer = 1) As Boolean
      Dim intPage, ingRec As Integer
      Dim strWholeFootnote, strPartFootnote, strRecTxt As String
      intPage = Selection.Information(3)
      ingRec = ActiveDocument.ActiveWindow.Panes(1).Pages(intPage).Rectangles.Count
      strRecTxt = ActiveDocument.ActiveWindow.Panes(1).Pages(intPage).Rectangles(ingRec).Range.Text
      strWholeFootnote = Len(Selection.Footnotes(iFootnote).Range.Text)
      strPartFootnote = Len(Mid(strRecTxt, InStrRev(strRecTxt, Chr(2)) + 1))
      If strWholeFootnote > strPartFootnote And InStr(strRecTxt, Chr(2)) = 0 Then
            fIsSplit = False
      ElseIf strWholeFootnote <= strPartFootnote Then
            fIsSplit = False
      Else
            fIsSplit = True
      End If
End Function

---

That function should work... But it requires you to select the footnote somewhere (either in the function or out of it). I don't thin you can get around this basic requirement because the selection while in print layout may be the only way to have the rectangles approach be reliable.

However, you need to give a broader context to what you're trying to achieve. Because I'm pretty sure the rectangles approach is going to slow down too once you start moving your selection around.

When are you performing this function? Some pieces of information are just slow (and get slower) when you're essential asking word for pagination information on large documents.

How you optimize your approach can only be answered by the context of when you're performing the function.

I think the for each loop in my approach might be able to be optimized a bit by checking the first word and the last word... Or some other way of getting that particular info, but optimization can take a long time, and can be a waste of time if you're trying to optimize without the big picture.

I am stabbing in the dark here because I've don't really understand the ultimate goal (footnotes can start looking freaky in multi-column text). Anyway, it seems (to me at least) that if the footnote starts in a rectangle on page(?) and ends in a rectangle on page(?) then it can't be split. So:

Code:

---

Sub Test()
    MsgBox fFootNoteIsSplit(1)
End Sub
 
Public Function fFootNoteIsSplit(ByRef lngFootnote As Long, _
    Optional oDoc As Document) As Boolean
    Dim oPage As Page
    Dim oRec As Rectangle
    Dim oFN As Footnote
    Dim oFNStart As Word.Range
    Dim oFNEnd As Word.Range
    Dim bStartonPage As Boolean
    Dim bEndonPage As Boolean
    Dim lngView As Long
    If oDoc Is Nothing Then Set oDoc = ActiveDocument
          lngView = oDoc.ActiveWindow.ActivePane.View.Type
          If lngView <> wdPrintView Then
              oDoc.ActiveWindow.ActivePane.View.Type = wdPrintView
          End If
          Set oFN = oDoc.Footnotes(lngFootnote)
          Set oFNStart = oFN.Range
          oFNStart.Collapse wdCollapseStart
          Set oFNEnd = oFN.Range
          oFNEnd.Collapse wdCollapseEnd
          Set oPage = oDoc.ActiveWindow.ActivePane.Pages(oFN.Range.Information(wdActiveEndPageNumber))
          bStartonPage = False
          bEndonPage = False
          For Each oRec In oPage.Rectangles
              If oFNStart.InRange(oRec.Range) Then
                    bStartonPage = True
                    Exit For
              End If
          Next oRec
          For Each oRec In oPage.Rectangles
              If oFNEnd.InRange(oRec.Range) Then
                    bEndonPage = True
                    Exit For
              End If
        Next oRec
          If bStartonPage And bEndonPage Then
              fFootNoteIsSplit = False
          Else
              fFootNoteIsSplit = True
          End If
          oDoc.ActiveWindow.ActivePane.View.ViewType = lngView
End Function

---

Frankly, I'm not sure myself what the end goal is, my colleague didn't explain and now she's on vacation...

Greg you latest seems to work properly and is pretty fast too. Thank You.