[VBA] How can I loop through the value of selected cells in a table?

I want to get msgbox the value of selected cells in a table.
Any hint how to do it?
Thanks.

Code:

---

    Dim Cell As Range
    For Each Cell In Selection.Cells
        MsgBox Cell.Cells.Value
    Next

---

Failed attempt. Thanks.

You need

Code:

---

Dim oCell As Cell
Dim oRng As Range
    For Each oCell In Selection.Cells
        Set oRng = oCell.Range 'Set a range to the cell
        oRng.End = oRng.End - 1 'remove the cell end character from the range
        MsgBox oRng.Text 'report the content
    Next oCell

---

:bow::bow::bow:

I you want it reduced to a single message box:

Code:

---

Sub ReturnCellText()
Dim strText As String
  strText = Replace(Selection.Range.Text, Chr(13) & Chr(7) & Chr(13) & Chr(7), Chr(13) & Chr(7))
  MsgBox Join(Split(strText, Chr(13) & Chr(7)), vbCr)
lbl_Exit:
  Exit Sub
End Sub

---

Simpler, if there are no paragraph breaks in the cells:

Code:

---

    Dim Cell As Range
    For Each Cell In Selection.Cells
        MsgBox Split(Cell.Range.Text, vbCr)(0)
    Next

---

This could be accumulated to a single output, too.

Likewise simpler even if there are paragraph breaks in the cells:

Code:

---

Dim Cell As Cell
  For Each Cell In Selection.Cells
    MsgBox Split(Cell.Range.Text, Chr(7))(0)
  Next
lbl_Exit:
  Exit Sub

---

Paul, did mean Dim oCell as Cell? As is, your code errors on the msgbox line.

Quote:

---

Originally Posted by gmaxey

Paul, did mean Dim oCell as Cell? As is, your code errors on the msgbox line.

---

I simply modified the OP's code without paying too much attention to how the variables had been declared. I agree, though, that reserved names should not be used that way.