Inserting text from VBA textbox into part of a string

Hi there, I'm new to VBA and hoping someone could help, if this might even be possible.

A date will be manually added by the user into TEXTBOX1.

.Bookmarks("BOOKMARK1").Range _
.InsertBefore TEXTBOX1

I have option buttons for the user to select which will place specific text and formatting (depending on the button selected) into the document as follows:

Code:

---

Private Sub OptionButton2_Click()
If Me.OptionButton2.Value = True Then
  Set oRng = ActiveDocument.Bookmarks("BOOKMARK2").Range
  oRng.Text = "EXAMPLE SENTENCE 1" & Chr(11) & Chr(9) & _
                      "EXAMPLE SENTENCE 2" & Chr(11) & _
                      "EXAMPLE SENTENCE 3" & vbNewLine & " "
  ActiveDocument.Bookmarks.Add "BOOKMARK2", oRng
  End If
End Sub

---

I am trying to get the date that has been entered in TEXTBOX1 to appear at the end of the sentence of EXAMPLE SENTENCE 2. Can anybody please help with this? Thank you!

Quite simple really. For example:

Code:

---

Private Sub CommandButton1_Click()
Dim Rng As Range, StrOut As String
If Me.OptionButton2.Value = True Then
    StrOut = "EXAMPLE SENTENCE 1" & Chr(11) & vbTab & _
            "EXAMPLE SENTENCE 2" & Chr(11) & _
            "EXAMPLE SENTENCE 3" & vbCr & " " & Me.TextBox1.Text
Else
    StrOut = ""
End If
With ActiveDocument
    Set Rng = .Bookmarks("BOOKMARK2").Range
    Rng.Text = StrOut
    .Bookmarks.Add "BOOKMARK2", Rng
End With
End Sub

---

More flexibly:

Code:

---

Private Sub CommandButton1_Click()
Dim BkMk As String, StrTxt As String
Call UpdateBookmark("BOOKMARK1", Me.TextBox1.Text)
If Me.OptionButton2.Value = True Then
  StrTxt = "EXAMPLE SENTENCE 1" & Chr(11) & vbTab & _
            "EXAMPLE SENTENCE 2" & Chr(11) & _
            "EXAMPLE SENTENCE 3" & vbCr & " " & Me.TextBox1.Text
Else
  StrTxt = ""
End If
Call UpdateBookmark("BOOKMARK2", StrTxt)
End Sub


Sub UpdateBookmark(BkMk As String, StrTxt As String)
Dim Rng As Range
With ActiveDocument
  Set Rng = .Bookmarks(BkMk).Range
  Rng.Text = StrTxt
  .Bookmarks.Add BkMk, Rng
End With
End Sub

---

Cross-posted at: ms word - Inserting text from VBA UserForm textbox into part of a string - Stack Overflow
Please read VBA Express' policy on Cross-Posting in Rule 3: http://www.vbaexpress.com/forum/faq...._new_faq_item3

Sincere apologies about the cross-post, I wasn't aware of this rule however, I've read the policy now. No disrespect to any volunteers was intended.

Thank you as well for your help! The simple way works perfectly for me and I'll keep it that way until I become more fluent in VBA and then I'll dabble into understanding the other method. Thanks again!

Quote:

---

Originally Posted by FmsBlnkr

Sincere apologies about the cross-post, I wasn't aware of this rule however, I've read the policy now. No disrespect to any volunteers was intended.

---

Its a very common rule amongst the forums.

I'm very new to VBA and these style of forums, so apologies again. Lesson learnt.