Using Dir() to return name of all images

Hello,

I am trying to write a simple macro that will check for any files with the term 'logo' in it, but this code doesn't seem to be working. There is a logo.jpg file in the current directory. Any ideas?

Code:

---

Sub Logocheck()

Dim ImgName As String
Dim ImgPath As String
ImgPath = ThisDocument.Path
ImgName = Dir(ImgPath & "logo.*")
MsgBox ImgName


End Sub

---

The actual application of this is will be to insert any image file with the name 'logo' in it, into the header of the word document.

This is only posted on this forum.

Change the line

Code:

---

ImgPath = ThisDocument.Path

---

to

Code:

---

ImgPath = ThisDocument.Path & "\"

---

better still

Code:

---

Sub Logocheck()
Dim ImgName As String
Dim ImgPath As String
    ImgPath = ThisDocument.Path
    ImgName = Dir$(ImgPath & "\*logo*")
    While ImgName <> ""
        MsgBox ImgName
        ImgName = Dir$()
    Wend
End Sub

---

Quote:

---

Originally Posted by gmayor

Change the line

Code:

---

ImgPath = ThisDocument.Path

---

to

Code:

---

ImgPath = ThisDocument.Path & "\"

---

better still

Code:

---

Sub Logocheck()
Dim ImgName As String
Dim ImgPath As String
    ImgPath = ThisDocument.Path
    ImgName = Dir$(ImgPath & "\*logo*")
    While ImgName <> ""
        MsgBox ImgName
        ImgName = Dir$()
    Wend
End Sub

---

---

Perfect! Thank you for this.

Works beautifully.

Not sure if this would require a new thread, but i am trying to parlay this into inserting the found image into the header of my document. I am getting Run-time error '5152' This is not a valid filename on the bolded line below:

Code:

---

Sub Logocheck()Dim oLogo As InlineShape
Dim ImgName As String
Dim ImgPath As String
Dim oSec As Section
Dim oHeader As HeaderFooter
    ImgPath = ThisDocument.Path
    ImgName = Dir$(ImgPath & "\*logo*")
    If ImgName = vbNullString Then
        MsgBox "Please note logo image was not found. You will need to manually insert the company logo into your final review."
    End If
    For Each oSec In ActiveDocument.Sections
        Set oHeader = oSec.Headers(wdHeaderFooterPrimary)
        With oHeader.Range
            .ParagraphFormat.Alignment = wdAlignParagraphRight
            Set oLogo = .InlineShapes.AddPicture(ImgName)
        End With
        With oLogo
            .LockAspectRatio = True
            .Height = 50
        End With
    Next oSec
End Sub

---

The issue is similar. ImgPath returns the name without the path. Change the line:

Code:

---

Set oLogo = .InlineShapes.AddPicture(ImgPath)

---

to

Code:

---

Set oLogo = .InlineShapes.AddPicture(ImgPath & "\" & ImgName)

---

also add

Code:

---

Exit Sub

---

after the message box.