Unable to batch delete hidden bookmarks in Word 2016

Version of the program: Word 2016
What you want it to do: I have a document which has quite a lot of bookmarks in it (both hidden and not), it seems like the user has removed its TOC but now also wants to remove the remaining "TOC and HIK" hidden bookmarks within the document. I have managed to find a macro which deletes any TOC and HIK bookmarks which are not hidden but for the life of me cannot figure out how to tell the macro to look for and delete the hidden bookmarks mentioned.
This is what I have been using which does delete non hidden bookmarks:

Code:

---

Dim aBookmark
For Each aBookmark In ActiveDocument.Bookmarks
If Left(aBookmark.Name, 3) = "TOC" Then
aBookmark.Delete
ElseIf Left(aBookmark.Name, 3) = "HIK" Then
aBookmark.Delete
End If
Next
End Sub

---

Error messages if any: None

Please note, this is my first time actually working with macros at all so please excuse my ignorance.

Thanks

Chris

Hidden bookmarks begin with an underscore _

Try adding 2 more ElseIf's for "_TOC" and "_HIK"

Quote:

---

Originally Posted by Paul_Hossler

Hidden bookmarks begin with an underscore _

Try adding 2 more ElseIf's for "_TOC" and "_HIK"

---

Hi Paul, thanks for the reply. I had also tried that earlier but they dont seem to get deleted?

I also saw another line of code on the web to try to "show" the hidden ones first before attempting to delete them but that did not work. That code was:

Code:

---

ActiveDocument.Bookmarks.ShowHidden = True

---

I also tried using an asterisk as a wildcard in the code (which is probably not even correct) as I thought the numbers after the named _TOC bookmarks were causing an issue but I dont think a wildcard is actually needed as I just created a standard bookmark called TOC8762862 and then ran the macro and that removed that bookmark just fine.

At its simplest:

Code:

---

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
With ActiveDocument
  For i = .Bookmarks.Count To 1 Step -1
    With .Bookmarks(i)
      If Left(.Name, 1) = "_" Then .Delete
    End With
  Next
End With
Application.ScreenUpdating = True
End Sub

---

Alternatively:

Code:

---

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
With ActiveDocument
  For i = .Bookmarks.Count To 1 Step -1
    With .Bookmarks(i)
      Select Case Left(.Name, 4)
        Case "_TOC", "_HIK": .Delete
      End Select
    End With
  Next
End With
Application.ScreenUpdating = True
End Sub

---

Try it:

Code:

---

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
  For i = ActiveDocument.Bookmarks.Count To 1 Step -1
      Select Case Left(ActiveDocument.Bookmarks(i).Name, 4)
        Case "_TOC", "_HIK", "RESU": ActiveDocument.Bookmarks(i).Delete
      End Select
  Next
Application.ScreenUpdating = True
End Sub

---

Quote:

---

Originally Posted by Emby

Try it:

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
For i = ActiveDocument.Bookmarks.Count To 1 Step -1
Select Case Left(ActiveDocument.Bookmarks(i).Name, 4)
Case "_TOC", "_HIK", "RESU": ActiveDocument.Bookmarks(i).Delete
End Select
Next
Application.ScreenUpdating = True
End Sub

---

Thanks both... I have run both of these options but when I'm going to bookmark another piece of text (to check if the other bookmarks remain) then it still shows them all :( If I select one of the _TOC bookmarks and click GO-TO then it still hops around the document to the bookmarks in question.

Attachment 25935

Please add "Ucase" to convert "_Toc" into "_TOC".

Code:

---

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
For i = ActiveDocument.Bookmarks.Count To 1 Step -1
Select Case Ucase(Left(ActiveDocument.Bookmarks(i).Name, 4))
Case "_TOC", "_HIK": ActiveDocument.Bookmarks(i).Delete
End Select
Next
Application.ScreenUpdating = True
End Sub

---

Quote:

---

Originally Posted by Emby

Please add "Ucase" to convert "_Toc" into "_TOC".

ub Demo()
Application.ScreenUpdating = False
Dim i As Long
For i = ActiveDocument.Bookmarks.Count To 1 Step -1
Select Case Ucase(Left(ActiveDocument.Bookmarks(i).Name, 4))
Case "_TOC", "_HIK": ActiveDocument.Bookmarks(i).Delete
End Select
Next
Application.ScreenUpdating = True
End Sub

---

I would like to thank you both for helping with this. I can understand how tiring it must be sometimes helping people who have no knowledge of the coding area of IT but you have really been super helpful and patient in this instance.

Once again thank you!

Just to say you need to set it to show hidden bookmarks.

I've also added a message showing the number deleted. May help others who find this via google search. I edited it to only delete _TOC... bookmarks because I can't find documentation about _HIK and there weren't any in my document.

Code:

---

Sub Demo()
Application.ScreenUpdating = False
ActiveDocument.Bookmarks.ShowHidden = True
Dim i As Long
Dim els As Long
For i = ActiveDocument.Bookmarks.Count To 1 Step -1
Select Case UCase(Left(ActiveDocument.Bookmarks(i).Name, 4))
Case "_TOC":
els = els + 1
ActiveDocument.Bookmarks(i).Delete
End Select
Next
MsgBox ("_Toc bookmarks deleted: " + CStr(els))
Application.ScreenUpdating = True
End Sub

---