I'm still not sure if I understand you but is this what you want:
[VBA]
Sub teset4()
Dim myDir As String, fn As String, a(), i As Integer, ws As Worksheet, LastR As Range
myDir = "C:\test\"
fn = Dir(myDir & "book1*.xls")
Do While fn <> ""
With Workbooks.Open(myDir & fn)
With ThisWorkbook.Sheets(1)
Set LastR = .Cells(LastCellInSheet(ThisWorkbook.Sheets(1)).Row + 2, "A")
End With
With .Sheets("7.07").UsedRange
LastR.Resize(.Rows.Count, .Columns.Count).Value = .Value
End With
.Close False
End With
fn = Dir()
Loop
End Sub
Public Function LastCellInSheet(wks As Worksheet) As Range
' Returns the cell at the bottom right corner of the sheet's real used range
Dim lngLastCol As Long, lngLastRow As Long
lngLastCol = 1
lngLastRow = 1
On Error Resume Next
With wks.UsedRange
lngLastCol = .Cells.Find(what:="*", after:=.Cells(1), _
SearchOrder:=xlByColumns, _
SearchDirection:=xlPrevious).Column
lngLastRow = .Cells.Find(what:="*", after:=.Cells(1), _
SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious).Row
End With
Set LastCellInSheet = wks.Cells(lngLastRow, lngLastCol)
End Function
[/VBA]
If not, then you will have to post a sample of your workbooks and what you want in the 'Big' workbook.
Regards,
Rory