Solved: Using is empty on a range

[grichey]

The goal is to highlight a range, run the macro, have all cells that are just #'s (not formulas) AND are not presently blank/empty multiplied by 1000.

I'm getting an error on the If and I know it has to do with my use of IsEmpty but I'm not sure how to rectify.

Thanks!

[VBA]Option Explicit
Sub puttothousands()
Dim c As Range

For Each c In Selection
If c.HasFormula = False And c.IsEmpty = False Then
c = c * 1000
End If
Next c
End Sub[/VBA]

[Bob Phillips]

[vba]

Sub puttothousands()
Dim c As Range

For Each c In Selection
If Not c.HasFormula And Not IsEmpty(c.Value) And IsNumeric(c.Value) Then
c = c * 1000
End If
Next c
End Sub
[/vba]

[grichey]

Thanks for helping shake the rust off. First use of VBA in months...

[Krishna Kumar]

Hi,

A non-loop approach..

[vba]Dim r As Range, tmp As Range
Set r = Selection
Set tmp = Range("iv1") ' a temporary cell
tmp = 1000
tmp.Copy
On Error Resume Next
r.SpecialCells(xlCellTypeConstants, 1).PasteSpecial , Operation:=xlMultiply
On Error GoTo 0
tmp.Clear
Application.CutCopyMode = 0[/vba]

HTH

[grichey]

Ya I realized I could've done the paste special. The loop method is nice and more easily modified for adding additional operations in the future.

Thanks!