Solved: Calendar control not working

[Richardall]

I have built a Word form that includes a field that that holds a date.

When you tab into the field, a response box pops up and asks "today" yes or no. If the answer is yes, the field is filled with today?s date. If no, a drop down calendar (frmCalendar.show) appears and the date can be chosen from that calendar.

So with some help from the Word help forum, I got the form to work. The problem is that it won't work on a Mac. The intent is to use mostly on PCs but there will be times that the file will be needed on the mac. I would also like to use this funtion on some other forms.

Can the calendar control work for the Mac? Could some VB code solve the problem? Is there any way one solution could work for both Mac and PC? Are there any suggestions?

Any suggestions and help are appreciated.

[shades]

It's been a while, but I think that Calendar is not supported on the Mac.

Jim McGimpsey's Response: It is an ActiveX control, which is not supported on Macs.

Jim is an MVP for Office for Mac.

[BlueCactus]

shades is correct. Calendar is an ActiveX thingie. No ActiveX thingies are supported in any Mac app that I'm aware of.

So, this one will require a bit of work. Might not actually be too hard to design a new tool from scratch. A weekend project, maybe. A stop gap measure might be to provide a form with month; day; year comboboxes for Mac users.

[Richardall]

I barely know aht and activieX control is and I doubt that I have a clue how to desing the combo box you mentioned. But I'm willing to learn!

I understand that both of you (Shades & BlueCactus) are the rainining experts for the Mac based question. Can you help?

If this to much to ask, I understand. Can you perhaps help me put in some code that will notify the Mac users that this filed won't work and to enter the date manually?

I'm completely new to the Forms and code but I would like to learn. At this point, the project meets the need and I can close the project, but I still think it could be better in the long run.

Any help would be appreciated.

Ricahrd

[BlueCactus]

Well, this provided a good opportunity for tinkering for my own benefit. I needed:
1) to work out how the hell VBA handles dates
2) to generate a calendar 'control' that I can later customize.

I may be reinventing the wheel here, but I don't care. It's a learning experience.

So, let me know what you think. I cannot upload a file right now, so this will require a little attention to detail. (Hint: double-clicking a toolbox button will allow you to keep dropping controls on a form without having to return to the toolbox each time.)

1. Insert a new form.
2. Name it 'DatePick'
3. Onto it, drop the following:

• 37 TextBoxes
• 8 text Labels
• 2 ComboBoxes
• 2 SpinButtons
• 1 CommandButton

Do not set names, positions or sizes - the code will take care of that.
4. Take a breath. (And drink a beer).
5. Double-click on the form, and replace ALL code with the following:
[vba]Dim dayNames As Variant, monthNames As Variant, daysMonth As Variant
Dim canUpdate As Integer, selectDate As Date

Sub FillVars(Optional sD As Date = 0)
Dim i As Integer, thisBox, thisLabel
Dim posX As Integer, posY As Integer, widthDay As Integer, heightDay As Integer

dayNames = Array("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat", "Sun")
monthNames = Array("January", "February", "March", "April", "May", "June", "July", "August", "September", "October", "November", "December")
daysMonth = Array(31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31)

If sD = 0 Then
selectDate = Date
Else
selectDate = sD
End If

canUpdate = 1

widthDay = 30
heightDay = 20

posX = widthDay / 2

With DatePick.Controls("Label8")
.Top = heightDay / 2
.Left = widthDay / 2
.Font.Size = 16
.Font.Bold = True
.Caption = monthNames(DatePart("m", Date) - 1) & " " & DatePart("yyyy", Date)
.Height = heightDay * 1.5
.Width = 150
End With

For i = 1 To 7
Set thisLabel = DatePick.Controls("Label" & i)

With thisLabel
.Caption = dayNames(i - 1)
.Font.Size = 10
.Font.Bold = True
.Top = heightDay * 2
.Left = posX
.Width = widthDay
.Height = heightDay
End With

posX = posX + widthDay
Next i

posX = widthDay / 2
posY = heightDay * 3

For i = 1 To 37
Set thisBox = DatePick.Controls("TextBox" & i)

With thisBox
.Top = posY
.Left = posX
.Width = widthDay
.Height = heightDay
End With

If i / 7 = Int(i / 7) Then
posX = widthDay / 2
posY = posY + heightDay
Else
posX = posX + widthDay
End If
Next i

posY = posY + heightDay

With ComboBox1
.Left = widthDay / 2
.Top = posY + heightDay / 2
.Width = widthDay * 3.5
.Height = heightDay

For i = 1 To 12
.AddItem monthNames(i - 1)
Next i
.ListIndex = DatePart("m", Date) - 1
.Style = fmStyleDropDownList
End With

With ComboBox2
.Left = widthDay * 5
.Top = posY + heightDay / 2
.Height = heightDay
.Width = widthDay * 2

For i = -9 To 10
.AddItem DatePart("yyyy", Date) + i
Next i
.ListIndex = 9
.Style = fmStyleDropDownList
End With

With SpinButton1
.Left = widthDay * 4
.Top = posY + heightDay / 2
.Height = heightDay
.Width = widthDay / 2
.Min = 0
.Max = 11
.Value = ComboBox1.ListIndex
End With

With SpinButton2
.Left = widthDay * 7
.Top = posY + heightDay / 2
.Height = heightDay
.Width = widthDay / 2
.Min = 0
.Max = 19
.Value = ComboBox2.ListIndex
End With

With CommandButton1
.Caption = "Cancel"
.Top = posY + heightDay * 2
.Height = heightDay
.Left = widthDay * 5.5
.Width = widthDay * 2
.Font.Size = 12
End With

With DatePick
.Width = 8 * widthDay
.Height = CommandButton1.Top + 2.5 * heightDay
.Caption = "Choose Date"
End With

Call SetDays(Date)

canUpdate = canUpdate - 1
End Sub

Private Sub ComboBox1_Change()
If canUpdate = 0 Then
canUpdate = canUpdate + 1
Label8.Caption = ComboBox1.Text & " " & ComboBox2.Text
Call SetDays(DateValue(ComboBox1.Text & " 1, " & ComboBox2.Text))
SpinButton1.Value = ComboBox1.ListIndex
canUpdate = canUpdate - 1
End If
End Sub

Private Sub ComboBox2_Change()
If canUpdate = 0 Then
canUpdate = canUpdate + 1
Label8.Caption = ComboBox1.Text & " " & ComboBox2.Text
Call SetDays(DateValue(ComboBox1.Text & " 1, " & ComboBox2.Text))
SpinButton2.Value = ComboBox2.ListIndex
canUpdate = canUpdate - 1
End If
End Sub

Private Sub CommandButton1_Click()
Unload DatePick
End Sub

Private Sub SpinButton1_Change()
ComboBox1.ListIndex = SpinButton1.Value
End Sub

Private Sub SpinButton2_Change()
ComboBox2.ListIndex = SpinButton2.Value
End Sub

Private Sub TextBox1_enter()
Call SetNewDate(TextBox1.Text)
End Sub
Private Sub TextBox2_enter()
Call SetNewDate(TextBox2.Text)
End Sub
Private Sub TextBox3_enter()
Call SetNewDate(TextBox3.Text)
End Sub
Private Sub TextBox4_enter()
Call SetNewDate(TextBox4.Text)
End Sub
Private Sub TextBox5_enter()
Call SetNewDate(TextBox5.Text)
End Sub
Private Sub TextBox6_enter()
Call SetNewDate(TextBox6.Text)
End Sub
Private Sub TextBox7_enter()
Call SetNewDate(TextBox7.Text)
End Sub
Private Sub TextBox8_enter()
Call SetNewDate(TextBox8.Text)
End Sub
Private Sub TextBox9_enter()
Call SetNewDate(TextBox9.Text)
End Sub
Private Sub TextBox10_enter()
Call SetNewDate(TextBox10.Text)
End Sub
Private Sub TextBox11_enter()
Call SetNewDate(TextBox11.Text)
End Sub
Private Sub TextBox12_enter()
Call SetNewDate(TextBox12.Text)
End Sub
Private Sub TextBox13_enter()
Call SetNewDate(TextBox13.Text)
End Sub
Private Sub TextBox14_enter()
Call SetNewDate(TextBox14.Text)
End Sub
Private Sub TextBox15_enter()
Call SetNewDate(TextBox15.Text)
End Sub
Private Sub TextBox16_enter()
Call SetNewDate(TextBox16.Text)
End Sub
Private Sub TextBox17_enter()
Call SetNewDate(TextBox17.Text)
End Sub
Private Sub TextBox18_enter()
Call SetNewDate(TextBox18.Text)
End Sub
Private Sub TextBox19_enter()
Call SetNewDate(TextBox19.Text)
End Sub
Private Sub TextBox20_enter()
Call SetNewDate(TextBox20.Text)
End Sub
Private Sub TextBox21_enter()
Call SetNewDate(TextBox21.Text)
End Sub
Private Sub TextBox22_enter()
Call SetNewDate(TextBox22.Text)
End Sub
Private Sub TextBox23_enter()
Call SetNewDate(TextBox23.Text)
End Sub
Private Sub TextBox24_enter()
Call SetNewDate(TextBox24.Text)
End Sub
Private Sub TextBox25_enter()
Call SetNewDate(TextBox25.Text)
End Sub
Private Sub TextBox26_enter()
Call SetNewDate(TextBox26.Text)
End Sub
Private Sub TextBox27_enter()
Call SetNewDate(TextBox27.Text)
End Sub
Private Sub TextBox28_enter()
Call SetNewDate(TextBox28.Text)
End Sub
Private Sub TextBox29_enter()
Call SetNewDate(TextBox29.Text)
End Sub
Private Sub TextBox30_enter()
Call SetNewDate(TextBox30.Text)
End Sub
Private Sub TextBox31_enter()
Call SetNewDate(TextBox31.Text)
End Sub
Private Sub TextBox32_enter()
Call SetNewDate(TextBox32.Text)
End Sub
Private Sub TextBox33_enter()
Call SetNewDate(TextBox33.Text)
End Sub
Private Sub TextBox34_enter()
Call SetNewDate(TextBox34.Text)
End Sub
Private Sub TextBox35_enter()
Call SetNewDate(TextBox35.Text)
End Sub
Private Sub TextBox36_enter()
Call SetNewDate(TextBox36.Text)
End Sub
Private Sub TextBox37_enter()
Call SetNewDate(TextBox37.Text)
End Sub

Private Sub SetNewDate(setDay As Integer)
If canUpdate = 0 Then
Call returnDate(DateValue(ComboBox1.Text & " " & setDay & ", " & ComboBox2.Text))
Unload DatePick
End If
End Sub

Private Sub UserForm_Initialize()
End Sub

Sub SetDays(tempDate As Date)
Dim i As Integer, Day, numDay As Integer

tempDate = DateValue(monthNames(DatePart("m", tempDate) - 1) & " 1, " & DatePart("yyyy", tempDate))

numDay = DatePart("w", tempDate)

If DatePart("yyyy", tempDate) / 4 = DatePart("yyyy", tempDate) \ 4 Then
daysMonth(1) = 29
Else
daysMonth(1) = 28
End If

If numDay > 1 Then
For i = 1 To numDay - 1
DatePick.Controls("TextBox" & i).Enabled = False
DatePick.Controls("TextBox" & i).Visible = False
Next i
End If

For i = 1 To daysMonth(DatePart("m", tempDate) - 1)
With DatePick.Controls("TextBox" & (numDay + i - 1))
.Visible = True
.Enabled = True
.Text = i
.Locked = True
.TabStop = False
.BackStyle = fmBackStyleTransparent
.ForeColor = RGB(0, 0, 0)
.Font.Bold = False
If DatePart("yyyy", Date) = ComboBox2.Text And monthNames(DatePart("m", Date) - 1) = ComboBox1.Text Then
If DatePart("d", Date) = i Then
.ForeColor = RGB(255, 0, 0)
.Font.Bold = True
End If
End If
If DatePart("yyyy", selectDate) = ComboBox2.Text And monthNames(DatePart("m", selectDate) - 1) = ComboBox1.Text Then
If DatePart("d", selectDate) = i Then .BackStyle = fmBackStyleOpaque
End If
End With
Next i

For i = daysMonth(DatePart("m", tempDate) - 1) + numDay To 37
With DatePick.Controls("TextBox" & i)
.Enabled = False
.Visible = False
End With
Next i
End Sub[/vba]

6. Insert a Module into the project.
7. Paste the following code into the new module:
[vba]Dim displayDate As Date

Sub test()
displayDate = DateValue("July 16, 2005")

Load DatePick

' If this code is in a form, the following shows how to place the calendar position at the calling control
' DatePick.startupposition = 3
' DatePick.Left = UserForm1.Left + CommandButton1.Left
' DatePick.Top = UserForm1.Top + CommandButton1.Top

' Note: If date not supplied to DatePick, current date will be used.
Call DatePick.FillVars(displayDate)
DatePick.Show

MsgBox "American notation: " & DatePart("m", displayDate) & "/" & DatePart("d", displayDate) & "/" & DatePart("yyyy", displayDate)
End Sub

Sub returnDate(dD As Date)
displayDate = dD
End Sub[/vba]
8. To test, run the macro named test()

Notes: 1) The date supplied to the form is highlighted in white. 2) The current date is highlighted in red. 3) Allowable year range can easily be expanded if needed. 4) The code can almost certainly be shortened. I'm still learning how to deal with dates. 5) If you use it in your app, test it well. Date handling is notoriously prone to unexpected bugs.

This form should work on Win VBA too, but I have not tested it there. The following code will allow you to do different stuff on Win or Mac:

[vba]If Instr(Application.OperatingSystem, "Windows") Then
' do Win VBA stuff
Else
' do Mac VBA stuff
End If [/vba]

[Scottie P]

"KB - KB - KB!!"

[BlueCactus]

Yeah, I'll send it that way soon. I need to tidy up a few loose ends first. Some of the code can be simplified / shortened. I originally wanted to make it a programatically constructed form (like brettdj's colour form), but I think there's too much code to make that worthwhile. I also have a couple of features to add.

[shades]

Excellent work! I agree, it should be a KB. I ran into another request like this just last week. Very timely!

[Scottie P]

Yes, it does work with Win Platform.
I set this up (WinXP Pro + Office XP Pro), took all of about 2-3 minutes with copy then paste + paste + paste for the Txtb^s and it ran nicely.

Take this one and run with it BC - as Shades has already mentioned, a Calendar Control variety for MAC is a sought after item (ran into that myself this past Saturday) and this would be a super addition to the Kb.

I think it's worth waiting for, indeed!

Can't wait to see what you do with it as a final work! Very nice!

Very cool!

[BlueCactus]

I'm glad to see that you guys think this is worth it.

Current version includes the following improvements:
A. Default date selection displayed in a new label.
B. Inclusion of a 'Find Today' button to help with long range calendar navigation.
C. Now operates in three modes:
[vba]DatePick(defaultDate as Date, mode as Integer, eventList as Variant)[/vba]
mode = 0

operates same as code above.

mode = 1

similar to mode 0, but picking a date just changes the date selection label. The Cancel button is now an OK button and is used to confirm the selection.

mode = 2 (under development, may or may not make it to KB)

indexes the day-of-the-month textboxes to event data stored in an array. Total # of events for given day is listed under each textbox. Selecting a day lists that day's events to a listbox. One or more events may be selected and sent back to the calling code.

The reason for mode 2 is that my spreadsheet maintains meta data concerning other files, part of which is a date stamp. I want to be able to choose files based on the calendar rather than the directory hierarchy.

If anyone has any desired features, I'll be glad to consider them (but obviously I won't promise them. )

[Richardall]

I'll follow your directions and try to incorporate this into a copy of my working file. If it works well, I'll be very thankful.

It also looks like many other will prosper form your work.

Nice job and thank you,

[lucas]

Hey guys,
I found this some time back and have been using it exclusivly. Even in Windows the native calendar control is not portable if they don't have the control in the system where you move it.

Works on sheet code but only pops up if you click a cell with a specific format.
might work on mac-don't know but worth a look.

This one is for excel

[MOS MASTER]

Hey guys,
I found this some time back and have been using it exclusivly. Even in Windows the native calendar control is not portable if they don't have the control in the system where you move it.

Works on sheet code but only pops up if you click a cell with a specific format.
might work on mac-don't know but worth a look.

This one is for excel

Hi,

What a beauty! Please do submit this one as well for a kb entry?

[shades]

I won't be able to try this on the Mac until this evening. But looks good in XL 2003 on Win 2K.

[Richardall]

Bluecactus, Thank you again for all the help. In one of your original replies, you mentioned that you couldn?t upload the file. Has that changed? Can you wrap this up and post it. I did what you said and I'm having some success, but...



Was wondering?



Thank you again.

[BlueCactus]

Bluecactus, Thank you again for all the help. In one of your original replies, you mentioned that you couldn?t upload the file. Has that changed? Can you wrap this up and post it.

Here you go. This one contains mode 0 and mode 1 listed above.

You can look at the file, but to use it in VBA requires code like:
[vba]Load DatePick
Call DatePick.FillVars
DatePick.Show[/vba]

Options are through...

DatePick.FillVars(defaultSelection, mode)

defaultSelection (optional, type Date) is the default date to be returned. If unspecified, Date (i.e., today's date) is used.

mode (optional, type Integer) is either 0 or 1 (default 0) in this revision.

mode 0: date returned immediately on clicking a day.
mode 1: date displayed on form when selected. Returned when user clicks 'OK' button. Allows user to select a date and hunt around the calendar some more before confirming the selection.

[7/7/05: File updated to fix a few minor cosmetic issues on Win VBA]
[7/7/05: File removed. Replaced with post #23]

[shades]

Lucas, I just tried your workbook with XL 2004 on Mac OS X (10.3.9 Panther). Works like a charm!

Thank you!!

[BlueCactus]

Lucas, I just tried your workbook with XL 2004 on Mac OS X (10.3.9 Panther). Works like a charm!

Thank you!!

Works on Excel X too, with one minor issue. In the form's initialize routine, you need one of my favorite lines of code:
[vba]CalendarFrm.Width = CalendarFrm.Width[/vba]

The Excel X will actually choose to display the whole form, instead of just part of it.

[lucas]

Works on Excel X too, with one minor issue. In the form's initialize routine, you need one of my favorite lines of code:
[vba]CalendarFrm.Width = CalendarFrm.Width[/vba]

The Excel X will actually choose to display the whole form, instead of just part of it.

Thanks for testing it guys. Bluecactus, I don't see a problem with adding that line to the form Initialize. I put it in just before the line:
CreateCal = True

[BlueCactus]

Here is the new enhanced three-mode calendar. I'm posting it here as a courtesy update to my previous file. I'll be cleaning up the code, bug testing and sending to KB in the next day or two, where full instructions will be provided.

Calendar mode is set in Module1.test() by changing the value of dpmode:
mode=0 : Simple calendar - click on a date to return it to the calling code.
mode=1 : Enhanced. Click on date to select, return with 'OK' button.
mode=2 : Event calendar. Click on date to select. Then select zero or more events. Click on 'OK' to return selected date, and selected events.

[7/8/2005: File removed; See post #25]