Macro wont run except...

[austenr]

This is a strange problem. I am trying to run the code below from the menu on the worksheet. If I do it that way it errors out on the .Documents.Add line. However, if you stay in the VBE and step through it using F8 it works.

Option Explicit

Sub CopyTableToAnyWordDocument()
Dim wdApp As Word.Application
ThisWorkbook.Sheets("Table").Range("A1:B6").Copy
On Error Resume Next
Set wdApp = GetObject(, "Word.Application")
If wdApp Is Nothing Then
   Set wdApp = GetObject(" ", "Word.Application")
End If
On Error GoTo 0
With wdApp
    .Documents.Add
    .Visible = True
End With
With wdApp.Selection
        .EndKey Unit:=wdStory
        .TypeParagraph
        .Paste
 End With
Set wdApp = Nothing
End Sub

I have attached the workbook also.

[Jacob Hilderbrand]

Looks like you are confusing Early and Late binding here. This should work for you.

Option Explicit
 
Sub CopyTableToAnyWordDocument()
Dim wdApp As Word.Application
ThisWorkbook.Sheets("Table").Range("A1:B6").Copy
Set wdApp = New Word.Application
With wdApp
    .Documents.Add
    .Visible = True
End With
With wdApp.Selection
        .EndKey Unit:=wdStory
        .TypeParagraph
        .Paste
 End With
Set wdApp = Nothing
End Sub

[mdmackillop]

Try

If wdApp Is Nothing Then
   Set wdApp = CreateObject("Word.Application")
End If

[austenr]

Both work..Thanks DRJ, MD Solved. Although I never could really grasp the Early and Late Binding concept. Can anyone briefly expalin. Thanks

[Justinlabenne]

How about here & here

[Bob Phillips]

Both work..Thanks DRJ, MD Solved. Although I never could really grasp the Early and Late Binding concept. Can anyone briefly expalin. Thanks

It is not necessarily anything to do with early/late-binding. CreateObject and GetObject work equally well with both. Binding referes to when the type library is bound to the application, early - before compilation, or late - at run time.