How to: If First 12 Characters in line = "/", Delete character

[l0aded]

As title says, I am trying to scan just the first 12 characters in each line and if it contains a "/" delete that character. So for example:

KB4024/AB
AC3402/AB

would become

KB4024AB
AC3402AB

I am fairly new to vba but I'd imagine it would need to use arrays? Another way that seems lengthy is to use
ActiveDocument.Paragraphs(n). _
Range.Characters(m) and just keep looping around till m reaches 12. Would this method work?

Thanks!

[macropod]

You could use a wildcard Find/Replace, without the need for VBA...
Find = ([^13^l][!^13^l/]{1,12})/
Replace = \1

[l0aded]

Didn't know about wildcards =X. Simple solutions to simple problems I suppose haha. Thanks

[Geoff]

Dim TargetString as String. ' the string to be searched
Dim Location as Integer
Dim ResultString as String. ' the string without the /

Location = Instr(TargetString, "/")

If Location = 0 Or Location >12 Then
ResultString = TargetString
' Because the / wasn't found (0) or
' wasn't in the first 12 characters (>12)
Else
ResultString = Left(TargetString, Location-1) & Right(TargetString, Len(TargetString) - Location)
End If


Geoff

[macropod]

Geoff: A straightforward Find/Replace would be far faster. The longer the document, the faster it would be by comparison.

[gmayor]

If you want Paul's replace function in a macro then

Dim oRng As Range
Set oRng = ActiveDocument.Range
With oRng.Find
Do While .Execute(FindText:="([^13^l][!^13^l/]{1,12})/", _
ReplaceWith:="\1", _
MatchWildcards:=True)
oRng.Collapse wdCollapseEnd
Loop
End With

should do the job.

[macropod]

Graham,

There's no need for the loop:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "([^13^l][!^13^l/]{1,12})/"
    .Replacement.Text = "\1"
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchWildcards = True
    .Execute Replace:=wdReplaceAll
End With
Application.ScreenUpdating = True
End Sub

[gmayor]

Indeed - more than one way to skin a cat

[Geoff]

Maybe I took the question too literally. I thought he only wanted to replace the / if it occurred in the first twelve characters and not if it was present further into the string.

Geoff

[macropod]

The F/R expression and code I've posted does only replace the / if it occurs in the first twelve characters. It ignores whatever may be further along.