You have been mixing your Excel and Word commands
The following should be closer to what you want. In the absence of your worksheet I will assume your Excel ranges are correct.
Sub Copy_Content()
Dim WordApp As Object
Dim WordDoc As Object
Dim WordPara As Object
Dim oRng As Object
Dim i As Long
Dim ExlRange As Excel.Range
'Copy content of selected row in CallsTaken and paste into Form
Worksheets("CallsTaken").Select
ActiveCell.Resize(, 13).Copy
Worksheets("Form").Select
Range("F8:F20").PasteSpecial Transpose:=True
'Copy contents of sheet 2 "Form to a Word Document
On Error Resume Next
Set WordApp = GetObject(, "Word.Application")
If Err Then
Set WordApp = CreateObject("Word.Application")
End If
On Error GoTo 0
'Make the Word window visaable
WordApp.Visible = True
WordApp.Activate
'maximise word window
WordApp.WindowState = 0 '0=Normal:1=Maximized:2=Minimized
'open existing word document
Set WordDoc = WordApp.Documents.Open("C:\Users\DELL User\Documents\0800WordDoc.docx")
'Select data to be copied and store in ExlRange
Set ExlRange = Worksheets("Form").Range("D8").Resize(13, 3)
ExlRange.Copy
Set oRng = WordDoc.Range
oRng.collapse 0
For i = 1 To 16
oRng.Text = oRng.Text & vbCr
Next i
oRng.collapse 0
oRng.PasteSpecial Link:=False, DataType:=10
'ExlRange.PasteSpecial?
Set WordApp = Nothing
Set WordDoc = Nothing
Set oRng = Nothing
Set ExlRange = Nothing
End Sub