The following will add the name and time, however that creates problems of its own because of illegal filename characters, so the date and time should be formatted as "yyyyMMdd_hhmm"and the sender name must be checked to eliminate illegal characters. Note also that the path should be terminated with the folder separator character and must exist unless you add code to create it if missing.
Option Explicit
'Updated 22 July 2021 by Graham Mayor - https://www.gmayor.com
Public Sub SaveAttachments()
Const strFolderpath As String = "H:\Saved Email Attachments\Test\"
Dim objOL As Outlook.Application
Dim objMsg As Object
Dim objAttachments As Outlook.Attachments
Dim objSelection As Outlook.Selection
Dim i As Long
Dim lngCount As Long
Dim strFile As String
On Error Resume Next
Set objOL = Application
Set objSelection = objOL.ActiveExplorer.Selection
' Check each selected item for attachments.
For Each objMsg In objSelection
Set objAttachments = objMsg.Attachments
lngCount = objAttachments.Count
If lngCount > 0 Then
' Use a count down loop for removing items
' from a collection. Otherwise, the loop counter gets
' confused and only every other item is removed.
For i = lngCount To 1 Step -1
' Get the file name and add received time and sender name.
strFile = Format(objMsg.ReceivedTime, "yyyyMMdd_hhmm") & _
"_" & objMsg.SenderName & _
"_" & objAttachments.Item(i).FileName
'Remove illegal filename characters
strFile = CleanFileName(strFile)
' Combine with the path to the folder.
strFile = strFolderpath & strFile
objAttachments.Item(i).SaveAsFile strFile
Next i
End If
Next
ExitSub:
Set objAttachments = Nothing
Set objMsg = Nothing
Set objSelection = Nothing
Set objOL = Nothing
End Sub
Private Function CleanFileName(strFileName As String) As String
Dim arrInvalid() As String
Dim lng_Index As Long
'Define illegal characters (by ASCII CharNum)
arrInvalid = Split("9|10|11|13|34|42|47|58|60|62|63|92|124", "|")
'Remove any illegal filename characters
CleanFileName = strFileName
For lng_Index = 0 To UBound(arrInvalid)
CleanFileName = Replace(CleanFileName, Chr(arrInvalid(lng_Index)), Chr(95))
Next lng_Index
lbl_Exit:
Exit Function
End Function