Split to Files - adjustment

[MrMap]

Hello,
I am trying to split an excel workbook into different files. I've found a macro online and it works great.

I forgot, however, that a number of fields in my spreadsheet have data validation. In addition to splitting the workbook I will also need to copy and paste an additional sheet where all of the domains are listed (the sheet is called 'LISTS').

I know very little about VBA but here is what I've done in the script below:

I've added a Dim for the sheet with all the domains (called 'Lists').

Dim lsh As Worksheet ' Lists Work Sheet

Next I tried to set the lsh object to refer to the specific worksheet in the workbook.

Set lsh = Sheets("LISTS")

However, this is as far as I can get. Did I set the "lsh" object correctly? Is there a way to set an object as a specific worksheet? Once I've set it what would be the syntax to call on the object to be copied?

I realize that I might be confusing concepts and I apologize. Any help would be welcome.

Thanks. See the code below.

Public Sub SplitToFiles()


' MACRO SplitToFiles
' Last update: 2018-05-15
' Original Author: mtone
' Edited By: MrMap
' Version 1
' Description:
' Loops through a specified column, and split each distinct values into a separate file by making a copy and deleting rows below and above
'
' Note: Values in the column should be unique or sorted.
'
' The following cells are ignored when delimiting sections:
' - blank cells, or containing spaces only
' - same value repeated
' - cells containing "total"
'
' Files are saved in a "Split" subfolder from the location of the source workbook, and named after the section name.


Dim osh As Worksheet ' Original sheet
Dim lsh As Worksheet ' Lists Work Sheet
Dim iRow As Long ' Cursors
Dim iCol As Long
Dim iFirstRow As Long ' Constant
Dim iTotalRows As Long ' Constant
Dim iStartRow As Long ' Section delimiters
Dim iStopRow As Long
Dim sSectionName As String ' Section name (and filename)
Dim rCell As Range ' current cell
Dim owb As Workbook ' Original workbook
Dim sFilePath As String ' Constant
Dim iCount As Integer ' # of documents created


iCol = Application.InputBox("Enter the column number you would like to use for splitting", "Select column", 2, , , , , 1)
iRow = Application.InputBox("Enter the starting row number (to skip header)", "Select row", 5, , , , , 1)
iFirstRow = iRow


Set osh = Application.ActiveSheet
Set owb = Application.ActiveWorkbook
Set lsh = Sheets("LISTS")
iTotalRows = osh.UsedRange.Rows.Count
sFilePath = Application.ActiveWorkbook.Path


If Dir(sFilePath + "\Split", vbDirectory) = "" Then
    MkDir sFilePath + "\Split"
End If


'Turn Off Screen Updating  Events
Application.EnableEvents = False
Application.ScreenUpdating = False


Do
    ' Get cell at cursor
    Set rCell = osh.Cells(iRow, iCol)
    sCell = Replace(rCell.Text, " ", "")


    If sCell = "" Or (rCell.Text = sSectionName And iStartRow <> 0) Or InStr(1, rCell.Text, "total", vbTextCompare) <> 0 Then
        ' Skip condition met
    Else
        ' Found new section
        If iStartRow = 0 Then
            ' StartRow delimiter not set, meaning beginning a new section
            sSectionName = rCell.Text
            iStartRow = iRow
        Else
            ' StartRow delimiter set, meaning we reached the end of a section
            iStopRow = iRow - 1


            ' Pass variables to a separate sub to create and save the new worksheet
            CopySheet osh, iFirstRow, iStartRow, iStopRow, iTotalRows, sFilePath, sSectionName, owb.fileFormat
            iCount = iCount + 1


            ' Reset section delimiters
            iStartRow = 0
            iStopRow = 0


            ' Ready to continue loop
            iRow = iRow - 1
        End If
    End If


    ' Continue until last row is reached
    If iRow < iTotalRows Then
            iRow = iRow + 1
    Else
        ' Finished. Save the last section
        iStopRow = iRow
        CopySheet osh, iFirstRow, iStartRow, iStopRow, iTotalRows, sFilePath, sSectionName, owb.fileFormat
        iCount = iCount + 1


        ' Exit
        Exit Do
    End If
Loop


'Turn On Screen Updating  Events
Application.ScreenUpdating = True
Application.EnableEvents = True


MsgBox Str(iCount) + " documents saved in " + sFilePath




End Sub


Public Sub DeleteRows(targetSheet As Worksheet, RowFrom As Long, RowTo As Long)


Dim rngRange As Range
Set rngRange = Range(targetSheet.Cells(RowFrom, 1), targetSheet.Cells(RowTo, 1)).EntireRow
rngRange.Select
rngRange.Delete


End Sub




Public Sub CopySheet(osh As Worksheet, iFirstRow As Long, iStartRow As Long, iStopRow As Long, iTotalRows As Long, sFilePath As String, sSectionName As String, fileFormat As XlFileFormat)
     Dim ash As Worksheet ' Copied sheet
     Dim awb As Workbook ' New workbook


     ' Copy book
     osh.Copy
     Set ash = Application.ActiveSheet


     ' Delete Rows after section
     If iTotalRows > iStopRow Then
         DeleteRows ash, iStopRow + 1, iTotalRows
     End If


     ' Delete Rows before section
     If iStartRow > iFirstRow Then
         DeleteRows ash, iFirstRow, iStartRow - 1
     End If


     ' Select left-topmost cell
     ash.Cells(1, 1).Select


     ' Clean up a few characters to prevent invalid filename
     sSectionName = Replace(sSectionName, "/", " ")
     sSectionName = Replace(sSectionName, "\", " ")
     sSectionName = Replace(sSectionName, ":", " ")
     sSectionName = Replace(sSectionName, "=", " ")
     sSectionName = Replace(sSectionName, "*", " ")
     sSectionName = Replace(sSectionName, ".", " ")
     sSectionName = Replace(sSectionName, "?", " ")


     ' Save in same format as original workbook
     ash.SaveAs sFilePath + "\Split\" + sSectionName, fileFormat


     ' Close
     Set awb = ash.Parent
     awb.Close SaveChanges:=False
End Sub

[SamT]

Moderator Bump.

[Fluff]

Try these changes

 CopySheet osh, lsh, iFirstRow, iStartRow, iStopRow, iTotalRows, sFilePath, sSectionName, oWB.fileFormat
Public Sub CopySheet(osh As Worksheet, lsh As Worksheet, iFirstRow As Long, iStartRow As Long, iStopRow As Long, iTotalRows As Long, sFilePath As String, sSectionName As String, fileFormat As XlFileFormat)
   ' Copy book
   Sheets(Array(osh.Name, lsh.Name)).Copy
   Set ash = Sheets(osh.Name)