Code to put Date & Time at the bottom of a user Contact form in OL 2010

[Witzker]

Hi
I have this code to put Date & Time at the bottom of a user Contact form in OL 2010 and put the cursor there.
the code ist started with a button in the form (vba or vbscript?)

Sub Datum_Click()
    Item.Body = Item.Body & vbCrLf & Date() & " - " & FormatDateTime(Time,4) & ": "
    Set objWSHShell = CreateObject("WScript.Shell")
    objWSHShell.SendKeys("{TAB 11}")
    objWSHShell.SendKeys("^{End}")
    objWSHShell.SendKeys("^{backspace}")

It would be great if this line would appear in Red in the form.

Can You pls assist?

[gmayor]

Try the following

Dim olInsp As Outlook.Inspector
Dim wdDoc As Object
Dim oRng As Object
    With Item
        .Display
        Set olInsp = .GetInspector
        Set wdDoc = olInsp.WordEditor
        Set oRng = wdDoc.Range
        oRng.collapse 0
        oRng.Text = vbCr & Date & " - " & FormatDateTime(Time, 4) & ": "
        oRng.Font.Color = &HFF
        oRng.collapse 0
        oRng.Select
    End With

[Witzker]

I put this in diese Outlook Sitzung

Public Sub DateRed()
    Dim olInsp As Outlook.Inspector
    Dim wdDoc As Object
    Dim oRng As Object
    With Item
        .Display
        Set olInsp = .GetInspector
        Set wdDoc = olInsp.WordEditor
        Set oRng = wdDoc.Range
        oRng.Collapse 0
        oRng.Text = vbCr & Date & " - " & FormatDateTime(Time, 4) & ": "
        oRng.Font.Color = &HFF
        oRng.Collapse 0
        oRng.Select
    End With
End Sub

when I open a contact and run it it says Objekt benötigt

[gmayor]

I assumed that you had already declared what 'Item' was You have to tell they macro what 'Item' is e.g.

Public Sub DateRed()
    Dim Item As Object
    Dim olInsp As Outlook.Inspector
    Dim wdDoc As Object
    Dim oRng As Object
    Set Item = ActiveExplorer.Selection.Item(1)
    If TypeName(Item) = "ContactItem" Then
        With Item
            .Display
            Set olInsp = .GetInspector
            Set wdDoc = olInsp.WordEditor
            Set oRng = wdDoc.Range
            oRng.collapse 0
            oRng.Text = vbCr & Date & " - " & FormatDateTime(Time, 4) & ": "
            oRng.Font.Color = &HFF
            oRng.collapse 0
            oRng.Select
        End With
    Else
        Beep
    End If
End Sub

[Witzker]

Great THX

I added
oRng.Text = vbCr & Date & " - " & FormatDateTime(Time, 4) & " Anruf: "

is it also possible to start the Telephone dialog from outlook with this macro?

[gmayor]

If it is possible I don't know how to do so and can find no on-line reference to the dialog.

[Witzker]

is it Possible to set the cursor at the end of the inserted date?

oRng.Text = vbCr & Date & " - " & FormatDateTime(Time, 4) & " Anruf: "

to write ther a coment

[gmayor]

oRng.collapse 0
oRng.Select

as in the original macro should do that.

[Witzker]

Yes

The text is inserted in red and is displayed at the end of the field even if there is more text in the field

BUT

The cursor is in another fields on the form !
If I start writing it is in another field

How to put cursor at the end of the inserted text in memo field?