Code Not called on button click

[NWE]

Hi,

So the following code works on it's own

Sub PullUniques()
With Sheets("Line Items")
    Dim rngCell As Range
    For Each rngCell In Range("A2:A1000")
        If WorksheetFunction.CountIf(Range("B2:B1000"), rngCell) = 0 Then
            Range("C" & Rows.Count).End(xlUp).Offset(1) = rngCell
        End If
    Next
    For Each rngCell In Range("B2:B1000")
        If WorksheetFunction.CountIf(Range("A2:A1000"), rngCell) = 0 Then
            Range("D" & Rows.Count).End(xlUp).Offset(1) = rngCell
        End If
    Next
End With
End Sub

but does not work in this button call:

Sub InsertIsolate()
    Call FileImport
    Call AuditLine
    Call AsBuiltLine
    Call PullUniques
End Sub

and I cannot figure out why..any thoughts?

[Dave]

U can trial this...

Sub PullUniques()
With Sheets("Line Items")
    Dim rngCell As Range
    For Each rngCell In .Range("A2:A1000")
        If WorksheetFunction.CountIf(.Range("B2:B1000"), rngCell) = 0 Then
            .Range("C" & .Rows.Count).End(xlUp).Offset(1) = rngCell
        End If
    Next
    For Each rngCell In .Range("B2:B1000")
        If WorksheetFunction.CountIf(.Range("A2:A1000"), rngCell) = 0 Then
            .Range("D" & .Rows.Count).End(xlUp).Offset(1) = rngCell
        End If
    Next
End With
End Sub

HTH. Dave

[p45cal]

Perhaps because your With…End With is never used:

Sub PullUniques()
With Sheets("Line Items")
    Dim rngCell As Range
    For Each rngCell In .Range("A2:A1000")
        If WorksheetFunction.CountIf(.Range("B2:B1000"), rngCell) = 0 Then
            .Range("C" & Rows.Count).End(xlUp).Offset(1) = rngCell
        End If
    Next
    For Each rngCell In .Range("B2:B1000")
        If WorksheetFunction.CountIf(.Range("A2:A1000"), rngCell) = 0 Then
            .Range("D" & Rows.Count).End(xlUp).Offset(1) = rngCell
        End If
    Next
End With
End Sub

[NWE]

Perhaps because your With…End With is never used:

Sub PullUniques()
With Sheets("Line Items")
    Dim rngCell As Range
    For Each rngCell In .Range("A2:A1000")
        If WorksheetFunction.CountIf(.Range("B2:B1000"), rngCell) = 0 Then
            .Range("C" & Rows.Count).End(xlUp).Offset(1) = rngCell
        End If
    Next
    For Each rngCell In .Range("B2:B1000")
        If WorksheetFunction.CountIf(.Range("A2:A1000"), rngCell) = 0 Then
            .Range("D" & Rows.Count).End(xlUp).Offset(1) = rngCell
        End If
    Next
End With
End Sub

Wait, what do you mean the With isn't used? I am confused

[p45cal]

Wait, what do you mean the With isn't used? I am confused

See https://docs.microsoft.com/en-us/off...6)%26rd%3Dtrue

You use that With…End With pair of statements, between which you'd expect to see some references beginning with just a dot; there are none.
I put big red dots in your code to show where they might be missing. Dave did a more thorough job of it.

[NWE]

See https://docs.microsoft.com/en-us/off...6)%26rd%3Dtrue

You use that With…End With pair of statements, between which you'd expect to see some references beginning with just a dot; there are none.
I put big red dots in your code to show where they might be missing. Dave did a more thorough job of it.

Yep..I see it...Thank you Pcal and Dave. I will give that a try and let you guys know what happened.

[NWE]

Yep..I see it...Thank you Pcal and Dave. I will give that a try and let you guys know what happened.

Yea that worked thanks guys.

[Dave]

You are welcome. Thanks for posting your outcome. Dave (and P45cal)