Consulting

Results 1 to 3 of 3

Thread: Outlook - Open dialogue box to confirm automatically BCC

  1. #1

    Outlook - Open dialogue box to confirm automatically BCC

    Any idea on adding a dialogue box prior to confirm or stop the command?

    Basically I want to automatically BCC an email address but have the ability to opt out of BCC'ing it as well.


    Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objRecip As Recipient
    Dim strMsg As String
    Dim res As Integer
    Dim strBcc As String
    On Error Resume Next

    ' #### USER OPTIONS ####
    ' address for Bcc -- must be SMTP address or resolvable
    ' to a name in the address book
    strBcc = "SomeEmailAddress"

    Set objRecip = Item.Recipients.Add(strBcc)
    objRecip.Type = olBCC
    If Not objRecip.Resolve Then
    strMsg = "Could not resolve the Bcc recipient. " & _
    "Do you want still to send the message?"
    res = MsgBox(strMsg, vbYesNo + vbDefaultButton1, _
    "Could Not Resolve Bcc Recipient")
    If res = vbNo Then
    Cancel = True
    End If
    End If

    Set objRecip = Nothing
    End Sub

  2. #2
    The following will prompt for each send and ask if you want to include the BCC

    Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objRecip As Recipient
    Dim strMsg As String
    Dim res As Integer
    Dim strBcc As String
        On Error Resume Next
    
        ' #### USER OPTIONS ####
        ' address for Bcc -- must be SMTP address or resolvable
        ' to a name in the address book
        strBcc = "someone@somewhere.com"
        
        res = MsgBox("Include BCC to " & strBcc & "?", vbYesNo + vbDefaultButton1)
        If res = vbYes Then
            Set objRecip = Item.Recipients.Add(strBcc)
            objRecip.Type = olBCC
            If Not objRecip.Resolve Then
                strMsg = "Could not resolve the Bcc recipient. " & _
                         "Do you want still to send the message?"
                res = MsgBox(strMsg, vbYesNo + vbDefaultButton1, _
                             "Could Not Resolve Bcc Recipient")
                If res = vbNo Then
                    Cancel = True
                End If
            End If
        End If
        Set objRecip = Nothing
    End Sub
    Graham Mayor - MS MVP (Word) 2002-2019
    Visit my web site for more programming tips and ready made processes
    http://www.gmayor.com

  3. #3
    Perfect!

    Thank you

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •