It appears from your code listing that you are trying to create from Excel a 'replytoall' message from the most recent message in Outlook's Inbox that has the string "City Pharmacy LLC" in the subject. In that case you want the following. Copy the indicated function from http://www.rondebruin.nl/win/s1/outlook/openclose.htm to the same module to ensure that Outlook is opened correctly, or the editing of the message body text may not work correctly.
Option Explicit
Sub TestMailTool()
'Graham Mayor - https://www.gmayor.com - Last updated - 21 Jan 2022
'Use the function from http://www.rondebruin.nl/win/s1/outlook/openclose.htm
'to open Outlook, or it will not work correctly
Dim olApp As Object
Dim olNS As Object
Dim olFolder As Object
Dim olItms As Object
Dim olMail As Object
Dim olItem As Object
Dim olInsp As Object
Dim wdDoc As Object
Dim oRng As Object
Dim i As Integer
Set olApp = OutlookApp() 'see note above
Set olNS = olApp.GetNamespace("MAPI")
Set olFolder = olNS.GetDefaultFolder(6)
Set olItms = olFolder.Items
olItms.Sort "[Received]", True
For i = 1 To olItms.Count
Set olMail = olItms(i)
If InStr(olMail.Subject, "City Pharmacy LLC") > 0 Then
Set olItem = olMail.replyall
With olItem
.display
.BodyFormat = 2 'html
Set olInsp = .GetInspector
Set wdDoc = olInsp.WordEditor 'access the message body for editing
Set oRng = wdDoc.Range
oRng.Collapse 1 'set a range to the start of the message
oRng.Text = "This is the message body text test reply." & vbCr & vbCr & _
"The default signature will be retained"
End With
Exit For
End If
Next i
lbl_Exit:
Set olApp = Nothing
Set olNS = Nothing
Set olFolder = Nothing
Set olItms = Nothing
Set olMail = Nothing
Set olItem = Nothing
Set olInsp = Nothing
Set wdDoc = Nothing
Set oRng = Nothing
Exit Sub
End Sub