Solved: Change the complicated names of the files in a folder as regular (1 - 2 - 3 ... n )

[Erdin? E. Ka]

Hi there,

I want to make regular (1 - 2 - 3 ... n ) name the files in a folder which files are ".bmp" surnamed instead of the complicated names.

For example:

The folder is:
C:\Pictures

The Files of this Directory:
ASAD.bmp
WER.bmp
SDLS.bmp
TEE.xls
FDFDL.doc
DPFDP.bmp
GKFLLF.jpg
LAST.bmp

My wish is;
Give new names only to .bmp surnamed files with a VBA code.

After code is running;

instead of ASAD.bmp : 1.bpm
instead of WER.bmp : 2.bpm
instead of SDLS.bmp : 3.bpm
TEE.xls : No changing
FDFDL.doc : No changing
instead of DPFDP.bmp : 4.bpm
GKFLLF.jpg : No changing
instead of LAST.bmp : 5.bpm

I tried some different ways to do it but i couldn't.

Thanks a lot.

[Bob Phillips]

[vba]

Sub LoopFolders()
Dim oFSO As Object
Dim Folder As Object
Dim Files As Object
Dim file As Object
Dim i As Long
Dim sPath As String


Set oFSO = CreateObject("Scripting.FileSystemObject")

sPath = "C:\Pictures"

Set Folder = oFSO.GetFolder(sPath)

For Each file In Folder.Files
If file.Type = "Bitmap Image" Then
MsgBox file.Path
i = i + 1
Name file.Path As Replace(file.Path, file.Name, i & ".bmp")
End If
Next file

Set oFSO = Nothing

End Sub
[/vba]

[mdmackillop]

[vba]Option Explicit
Sub ReNames()
Dim MyPath As String, MyName As String, i As Long
MyPath = "C:\Pictures\"
MyName = Dir(MyPath)
Do While MyName <> ""
If UCase(Right(MyName, 3)) = "BMP" Then
i = i + 1
Name MyPath & MyName As MyPath & i & ".bmp"
End If
MyName = Dir
Loop
End Sub
[/vba]

[malik641]

[VBA]Option Explicit
Option Compare Text

Sub ChangeBMP()
Dim path As String
Dim i As Long
path = "C:\Pictures\"

With Application.FileSearch
.NewSearch
.LookIn = path
.Filename = "*.bmp"
If .Execute() > 0 Then
For i = 1 To .FoundFiles.Count
Name CStr(.FoundFiles(i)) As path & i & ".bmp"
Next
End If
End With
End Sub[/VBA]

[Erdin? E. Ka]

Soo fast solutions.!

I wanted just only one "eye" from God, God gave me three eyes!!

Thank you very much mdmackillop and xld and malik641, these are perfect.

[malik641]

thank you very much msmackillop and malik641, these are perceft.

Well, I didn't know Ms. mackillop was writing your code for you


and no problem

BTW, I noticed you changed it....that's okay...it's still funny to me

[malik641]

Hey Bob,

When it comes to file manipulation I've noticed you seem to like to use the FileSystemObject approach...so why do you use the Name file As new_name method when you could use the .Move or .MoveFile methods?

Just wondering

[Erdin? E. Ka]

Well, I didn't know Ms. mackillop was writing your code for you


and no problem

BTW, I noticed you changed it....that's okay...it's still funny to me

Excuse me, i wrote quickly and did it wrong.

[Bob Phillips]

Hey Bob,

When it comes to file manipulation I've noticed you seem to like to use the FileSystemObject approach...so why do you use the Name file As new_name method when you could use the .Move or .MoveFile methods?

Just wondering

I use FSO because both FileSearch and Dir are flawed, but when I can use pur VB I do.

[malik641]

I use FSO because both FileSearch and Dir are flawed, but when I can use pur VB I do.

I see.



Just when I liked my solution too

[Erdin? E. Ka]

...I wanted just only one "eye" from God, God gave me three eyes!...

Just a little correction:

It's a Turkish Proverb:
The blindman wished just only 1 eye from God, then God gave him 3 eyes.

Thanks again to kindly helps. See you.