Okay... here we go!

I've rewritten a bunch to get the progress bar working, so you'll want to review this carefully. Some things to note:
-You no longer need the "FolderExists" or "CountFiles" functions, as I have rolled them both into the cmdOkay routine of the userform
-In addition, the count of the files now is passed to the FindAll routine so that it doesn't need to be recalculated
-The progress indicator has replaced the statusbar, but it most likely will slow things down a bit. At least you get to watch something though, I guess It is 4-5 lines of code instead of 1, which gives rise to the speed concern, but hopefully it isn't too much
-The userform now expands and shrinks to show/hide the progress indicator
-I've attached a zipped copy of the userform that I've been working with as I think it's easier that way than trying to explain it. If your userform is called ufSearch, you will want to rename it before you attempt to import this one
-I have not done much to the file searching at this point. That is going to take a little while to read up on around the net (thanks for the posts, MD, those will be helpful). I figured that speed could probably come later, as long as the main view is there first. (Again, at least giving your users something to watch while the wait )


So here's all the code... In the regular module:
[vba]Option Compare Text
Option Explicit
Sub FindAll(SearchPath As String, SearchText As String, ToProcess As Integer)
'Macro purpose: Loop through all Excel Workbooks and search each of them for the
'specified criteria
Dim WB As Workbook
Dim WS As Worksheet
Dim FileName As String
Dim TermFound As Boolean
Dim i As Integer, x As Integer
Dim Processed As Integer
Dim BoxText As String
Dim Problem As Boolean

'Turn off screen flashing & taskbar updates
With Application
.ScreenUpdating = False
.ShowWindowsInTaskbar = False
End With

'Assign first filename in directory to FileName variable
FileName = Dir(SearchPath & "\*.xls", vbNormal)

'Expand ufSearch to show progress bar
With ufSearch
.Height = 174
.Repaint
End With

Do
'Set problem to false then attempt to open workbook and set WB & WS variables
'(If an error results, set the Problem variable to true)
Problem = False
On Error Resume Next
Set WB = Workbooks.Open(FileName:=SearchPath & "\" & FileName, ReadOnly:=True) _
', Password:="Uncomment and put password here if required"
If Err.Number <> 0 Then Problem = True
On Error Resume Next

If Problem = True Then
'If an error resulted, (Problem is True,) close the workbook
'(On error resume next in case WB never opened at all)
On Error Resume Next
WB.Close False
On Error GoTo 0

Else
TermFound = False
For Each WS In WB.Worksheets
'If no error, check all textboxes in the file for search term
For i = 1 To WS.TextBoxes.Count
BoxText = WS.TextBoxes(i).Text
If InStr(1, BoxText, SearchText) > 0 Then
'If the search term is found, set TermFound to true,
'and stop checking further (exit the loop)
TermFound = True
Exit For
End If
Next i
If TermFound = True Then Exit For
Next WS
If TermFound = False Then
'If the search term was not found, close the file
WB.Close False
Else
'If the search term was found, add 1 to the count of
'opened files using x as variable to hold the info
x = x + 1
End If
End If

'Inform the user how many files have been processed and update the progress bar
Processed = Processed + 1
Call UpdateProgress(Processed / ToProcess)

'Release WB & WS variables and set FileName to next file
Set WB = Nothing
Set WS = Nothing
FileName = Dir() 'sets FileName to next file in directory
Loop Until FileName = ""

'Restore screen updating, show open files on taskbar and clear statusbar
With Application
.ScreenUpdating = True
.ShowWindowsInTaskbar = True
End With

'Hide the progress indicator
With ufSearch
.Hide
End With

'Inform the user how many files were opened (number of opend files held in x)
MsgBox x & " files were found which matched your search term!", _
vbOKOnly + vbInformation, x & " Files Found!"

End Sub
Sub UpdateProgress(PctDone As Single)
'Source: John Walkenbach's Excel 2002 Power Programming with VBA
'Purpose: To update the ufSearch userform
With ufSearch
.frmProgress.Caption = Format(PctDone, "0%")
.lblProgress.Width = PctDone * (.frmProgress.Width - 10)
.Repaint
End With
End Sub[/vba]

And in the userform:
[vba]Option Explicit
Private Sub cmdOkay_Click()
Const MainPath = "\\Disk1\Stockdata\Year\"
Dim Prompt As String, _
FilesToProcess As Integer, _
fso As Object, _
FullFilePath As String
'Make sure both textboxes have values assigned
If Not IsDate(tbDate.Value) Then Prompt = "Please enter a prompt date" & vbCrLf
If tbSearch.Value = "" Then Prompt = Prompt & "Please enter something to search for"

'If Prompt is empty, then no problems were detected
If Prompt = "" Then
'Create a file scripting object and set the FullFilePath variable
Set fso = CreateObject("Scripting.FileSystemObject")
FullFilePath = MainPath & Year(tbDate) & "\" & Format(tbDate, "mmm")

'Check if the file path exists, and count the number of files in it
If fso.FolderExists(FullFilePath) Then
FilesToProcess = fso.GetFolder(FullFilePath).Files.Count
If FilesToProcess > 0 Then
'If folder for the month exists & has files in it, call FindAll routine
Call FindAll(FullFilePath, tbSearch.Value, FilesToProcess)
Unload Me
Else
'If no files are in the directory, inform the user
MsgBox "The information you entered generated a file path of:" & _
vbCrLf & MainPath & Year(tbDate) & "\" & Format(tbDate, "mmm") & _
vbCrLf & vbCrLf & "There are no files in that directory!" & vbCrLf & _
"Please modify your selection and try again!", _
vbOKOnly + vbCritical, "Directory is empty!"
End If
Else
'If the folder for the month does not exist, notify the user
MsgBox "The information you entered generated a file path of:" & vbCrLf & _
MainPath & Year(tbDate) & "\" & Format(tbDate, "mmm") & vbCrLf & vbCrLf & _
"That file path does not exist! Please modify your selection and try again!", _
vbOKOnly + vbCritical, "Folder does not exist!"
End If
Else
'If Prompt is not empty, tell the user what info need correcting and return to the
'userform
MsgBox "Sorry, but I need more information!" & vbCrLf & Prompt, _
vbCritical + vbOKOnly, "Hang on!"
End If
End Sub
Private Sub cmdCancel_Click()
'Unload the userform
Unload Me
End Sub
Private Sub UserForm_Initialize()
'Shrink userform so progress bar doesn't show
Me.Height = 108
'Put today's date in the userform
tbDate.Value = Format(Now(), "d-mmm-yyyy")
End Sub[/vba]

To import the attached, right click on your forms directory and choose "import" (but remember to change your userform first if it's name is ufSearch!)

Now it's time for me to go too!