If you would name your column titles with something like InmateAssaultCol or InmateAssualt2 similar to your named ranges using a suffix like those or a prefix for the total range names, you can make the function more concise without the need to add more Cases.

[vba]Sub BCMerge()
Dim pappWord As Object
Dim docWord As Object
Dim wb As Excel.Workbook
Dim xlName As Excel.Name
Dim TodayDate As String
Dim Path As String

Set wb = ActiveWorkbook
TodayDate = Format(Date, "mmmm d, yyyy")
Path = wb.Path & "\Monthly_Report.dot"

On Error GoTo ErrorHandler

'Create a new Word Session
Set pappWord = CreateObject("Word.Application")

On Error GoTo ErrorHandler

'Open document in word
Set docWord = pappWord.Documents.Add(Path)

'Loop through names in the activeworkbook
For Each xlName In wb.Names
'if xlName's name is existing in document then put the value in place of the bookmark
If docWord.Bookmarks.Exists(xlName.Name) Then
'docWord.Bookmarks(xlName.Name).Range.Text = Range(xlName.Value)
docWord.Bookmarks(xlName.Name).Range.Text = iReport(xlName)
iReport xlName
End If
Next xlName

'Activate word and display document
With pappWord
.Visible = True
.ActiveWindow.WindowState = 0
.Activate
End With

'Release the Word object to save memory and exit macro
ErrorExit:
Set pappWord = Nothing
Exit Sub

'Error Handling routine
ErrorHandler:
If Err Then
MsgBox "Error No: " & Err.Number & "; There is a problem"
If Not pappWord Is Nothing Then
pappWord.Quit False
End If
Resume ErrorExit
End If
End Sub

Function iReport(theName As Name)
Debug.Print theName.Name
Dim s As String, col As String
Dim cell As Range, rn As Long

Select Case theName.Name
Case "StaffAssault"
col = "E"
Case "InmateAssault"
col = "F"
Case "PREA"
col = "H"
Case "UOF"
col = "J"
Case Else
col = ""
End Select

If col = "" Or Range(theName.Name).Value = "" Then
iReport = ""
Exit Function
End If

s = "total " & Range(theName.Name).Value & " Report Number(s) "
rn = Range("B" & Rows.Count).End(xlUp).Row
For Each cell In Range(col & "5", Range(col & rn))
If cell.Value = "" Then GoTo NextCell
s = s & Range("B" & cell.Row).Value & ", "
NextCell:
Next cell

s = Left(s, Len(s) - 2)
iReport = s
End Function

[/vba]