Going through every instance of a string in text boxes

[John Wilson]

This is how to do that the original code is by my friend Shyam and there is a more complex version on his site.

Sub GlobalFindAndReplace()' original code by Shyam Pillai
' more complex version
' http://skp.mvps.org/ppt00025.htm#2
Dim oPres As Presentation
Dim oSld As Slide
Dim oShp As Shape
Dim FindWhat As String
Dim ReplaceWith As String


FindWhat = "ß2"
ReplaceWith = "ß" & ChrW(8322)
For Each oPres In Application.Presentations
     For Each oSld In oPres.Slides
        For Each oShp In oSld.Shapes
            Call ReplaceText(oShp, FindWhat, ReplaceWith)
        Next oShp
    Next oSld
Next oPres
End Sub


Sub ReplaceText(oShp As Object, FindString As String, ReplaceString As String)
Dim oTxtRng As TextRange
Dim oTmpRng As TextRange
Dim I As Integer




    If oShp.HasTextFrame Then
        If oShp.TextFrame.HasText Then
            Set oTxtRng = oShp.TextFrame.TextRange
            Set oTmpRng = oTxtRng.Replace(FindWhat:=FindString, _
                Replacewhat:=ReplaceString, WholeWords:=True)
            Do While Not oTmpRng Is Nothing
                Set oTmpRng = oTxtRng.Replace(FindWhat:=FindString, _
                            Replacewhat:=ReplaceString, _
                            After:=oTmpRng.Start + oTmpRng.Length, _
                            WholeWords:=True)
            Loop
       End If
    End If


End Sub