Converting glossary to footnotes

[macropod]

A Word macro to do as you describe is:

Sub Demo()
Application.ScreenUpdating = False
Dim Tbl As Table, StrFnd As String, Rng As Range, FtNt As Footnote, r As Long
With ActiveDocument
  Set Tbl = .Tables(.Tables.Count)
  Tbl.Range.Style = wdStyleFootnoteText
  For r = 1 To Tbl.Rows.Count
    Set Rng = Tbl.Cell(r, 2).Range
    Rng.End = Rng.End - 1
    StrFnd = Trim(Split(Tbl.Cell(r, 1).Range.Text, vbCr)(0))
    With .Range
      With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Format = False
        .Text = StrFnd
        .Wrap = wdFindStop
        .MatchWholeWord = True
        .MatchWildcards = False
        .MatchCase = True
        .Execute
      End With
      .Collapse wdCollapseEnd
      Set FtNt = .Footnotes.Add(Range:=.Duplicate)
      With FtNt.Range
        .FormattedText = Rng.FormattedText
        .CollapsewdCollapseStart
        .Text = StrFnd & ": "
        .Style = wdStyleStrong
      End With
    End With
  Next
  Tbl.Delete
End With
Application.ScreenUpdating = True
End Sub