I helped a person on another site copy objects from Excel into an email in Outlook, you need to access the Word document part of the email in order to add such objects. The is the code I gave them, maybe it'll help you.

    On Error GoTo ErrorHandler


    ' setup your objects
    Dim charts As ChartObjects
    Dim chrt As ChartObject

    Dim olApp As Outlook.Application
    Dim olMail As Outlook.MailItem
    Dim olInspector As Outlook.Inspector

    Dim olEditor As Word.Document
    Dim wdRange As Word.Range

    Dim chartCount As Integer

    ' assign the values
    Set charts = Sheet1.ChartObjects

    Set olApp = New Outlook.Application
    Set olMail = olApp.CreateItem(olMailItem)

    ' create an email in outlook
    chartCount = 1
    With olMail

        .To = "[**** TO EMAIL HERE ***]"
        .Subject = "Sending Charts"
        .Display

        Set olInspector = .GetInspector
        Set olEditor = olInspector.WordEditor
        Set wdRange = olEditor.Range(0, olEditor.Characters.Count)
        wdRange.InsertAfter "This email contains the charts you requested" & vbCr

        ' add each chart on the sheet to the outlook email
        For Each chrt In charts
            chrt.Copy

            wdRange.InsertParagraphAfter
            olEditor.Paragraphs(chartCount + 1).Range.Paste

            chartCount = chartCount + 1
        Next chrt
    End With

    olMail.Send
    olApp.Session.SendAndReceive True

    ' close outlook and clean up the objects
    'olApp.Quit

    Set olInspector = Nothing
    Set olEditor = Nothing
    Set olMail = Nothing
    Set olApp = Nothing


    MsgBox "The email has been sent"


Exit Sub

ErrorHandler:


    MsgBox "The email could not be sent. Error: " & Error(Err.Number)

    On Error Resume Next
    If Not IsNull(olApp) Then olApp.Quit

    Set olInspector = Nothing
    Set olEditor = Nothing
    Set olMail = Nothing
    Set olApp = Nothing