How to list dates defined by a data validation process

[Bob Phillips]

The following formulas could be secret rocket launch codes for all I know. Just exactly what do they mean, and remember you are speaking with a convict here so go gently with the wording.

=VALUE(TEXTSPLIT(TEXTJOIN("¬",TRUE,BYROW(R36#,LAMBDA(i,TEXTJOIN("¬",TRUE,SEQUENCE(,TAKE(i,,1),TAKE(i,,-1)))))),,"¬",TRUE))

and

=VALUE(TEXTSPLIT(TEXTJOIN("¬",TRUE,BYROW(R36#,LAMBDA(i,TEXTJOIN("¬",TRUE,SEQUENCE(,TAKE(i,,1),TAKE(i,,-1)))))),Table1__2[@Date],"¬",TRUE))

and this one is

=LAMBDA(myDates,maxes,celsius,LET(g,SORT(FILTER(myDates,ABS(maxes-celsius)<=1)),f,SORT(g)-SEQUENCE(COUNT(g)), _
e,UNIQUE(f),c,DROP(FREQUENCY(f,e),-1),d,XLOOKUP(e,f,g),b,FILTER(HSTACK(c,d),c>=3),result,TEXTSPLIT(TEXTJOIN("¬",TRUE, _
BYROW(b,LAMBDA(i,TEXTJOIN("¬",TRUE,SEQUENCE(,TAKE(i,,1),TAKE(i,,-1)))))),,"¬",TRUE),b))(A2:A78,B2:B78,Temperature)

I'll have a go at partially answering Ted.

First, note that LET is a way of doing a step by step calculation, similar to using helper cells, all in one formula. So you declare a variable, and then assign a value or a function to that variable, you can use that variable in a later step,

LAMBDA is a a custom function, somewhat akin to a UDF, and you declare the parameters that are passed to the LAMBDA function up front, then the code to process those parameters.

If you stagger the code you can better see each step and you should be able to work out what each step does.

=LAMBDA(myDates,maxes,celsius, 
        LET(g,SORT(FILTER(myDates,ABS(maxes-celsius)<=1)),
            f,SORT(g)-SEQUENCE(COUNT(g)),
            e,UNIQUE(f),
            c,DROP(FREQUENCY(f,e),-1),
            d,XLOOKUP(e,f,g),
            b,FILTER(HSTACK(c,d),c>=3),
result,TEXTSPLIT(TEXTJOIN("¬",TRUE, BYROW(b,LAMBDA(i,TEXTJOIN("¬",TRUE,SEQUENCE(,TAKE(i,,1),TAKE(i,,-1)))))),,"¬",TRUE),b)
       )(A2:A78,B2:B78,Temperature)

... what the hell is this? "¬". What was it meant to be before it got smashed by a truck?

That is just a character being used as a delimiter, it is one that is unlikely to occur in any of your data (I always use CHAR(1) to achieve the same).