Hmm... to do anything else, I'd really need to double-check information about the controls on your form. Ideally, it'd be best to have an example of the database attached to the thread, but as I recall you ran into some difficulties attempting that earlier. So instead, I created a script you can run that will put the necessary information into a text file. Just follow these steps:

1. In your Access database, open the VB Editor.
2. Select Insert / Module from the menu.
3. Copy and Paste the following code into your new module.
[VBA]
Option Compare Database
Option Explicit

Const frmName As String = "NordersMaken"
Const outputPath As String = "C:\controls.txt"

Public Sub getControlData()
Dim fs As Object
Dim ts As Object
Set fs = CreateObject("Scripting.FileSystemObject")
Set ts = fs.CreateTextFile(outputPath)
ts.WriteLine "Name, Type, Source, Parent"
DoCmd.OpenForm frmName
extractData Forms(frmName), ts
ts.Close
Set ts = Nothing
Set fs = Nothing
End Sub

Private Sub extractData(o As Object, ts As Object, Optional p As String = "")
Dim c As Control
For Each c In o.Controls
ts.WriteLine getProperty(c, "Name") & ", " & getProperty(c, "ControlType") & ", " & _
getProperty(c, "ControlSource") & ", " & p
If StrComp(getProperty(c, "ControlType"), "112") = 0 Then
extractData c, ts, c.Name
End If
Next
End Sub

Private Function getProperty(c As Control, s As String) As String
On Error GoTo PropertyError
If s = "Name" Then
getProperty = c.Name
ElseIf s = "ControlType" Then
getProperty = c.ControlType
ElseIf s = "ControlSource" Then
getProperty = c.ControlSource
End If
Exit Function
PropertyError:
getProperty = ""
End Function
[/VBA]
4. Optional step: If you want the text file to be created someplace other than the C: drive, change the value of outputPath (located at the top of the code) to the path and filename you wish to use.
5. Select Run / Run Sub/UserForm from the menu. If prompted, select "getControlData" and click the Run button.
6. If the program runs without errors, it should create a new text file (located in the main directory of your C: drive unless you changed it above). Open that file and copy/paste its contents to here.

If the program does create an error, let me know what the error message says.