Sub ExportToExcelDAO() 
     'requires reference to Microsoft Excel Object Library
     
    Dim db As DAO.Database 
    Dim rst As DAO.Recordset 
    Dim xlApp As Object 
    Dim wkb As Object 
    Dim rng As Object 
    Dim strExcelFile As String 
    Dim strTable As String 
    Dim iCol As Integer 
    Dim rowsToReturn As Integer 
    Dim objSheet As Object 
    Dim tblrst As DAO.Recordset 
     
    Set db = CurrentDb '<<<Connect to this currently open database
     'connect to primary table
    Set tblrst = db.OpenRecordset("tblEmployeeInfo") '<<<***Replace with your Primary Table's Name***
     
    tblrst.MoveFirst '<<<move to the first record of primary table
     
    Do Until tblrst.EOF '<<<Loop commands until end of recordset reached
         'SQL statement used to query chosen records in data table
         'tblrst!EmployeeID pulls data from the EmployeeID field
        strTable = "SELECT tblOrders.* FROM tblOrders INNER JOIN tblEmployeeInfo " _ 
        & "ON tblOrders.EmployeeID = tblEmployeeInfo.EmployeeID " _ 
        & "WHERE (([tblEmployeeInfo].[EmployeeID]= " & tblrst!EmployeeID & "));" 
         '^<<<You must use a Bang (!) between tblrst & field name to get the field's value
         
        strExcelFile = "C:\Test\" & tblrst!EmpName '<<<Creates new excel file named for current primary table's field value
        Set rst = db.OpenRecordset(strTable) '<<<Open query results from data table for primary table's current field value
         
         'get number of records in recordset
        rst.MoveLast '<<<Required to get total number of records in recordset
        rowsToReturn = rst.RecordCount 
        rst.MoveFirst '<<<Move back to start of recordset
         '^ if MoveFirst is not used then only last record will be gathered
         
        If rowsToReturn <= rst.RecordCount Then '<<<Do as long as there are records to work
             'set reference to Excel to make Excel visible
            Set xlApp = CreateObject("Excel.Application") 
            xlApp.Application.Visible = True '<<<Change to False to make Excel invisible
             'set references to workbook and worksheet
            Set wkb = xlApp.Workbooks.Add '<<<Create new workbook
            Set objSheet = xlApp.ActiveWorkbook.Sheets(1) '<<<Add worksheet to workbook
             
             'write column names to the first worksheet row
            For iCol = 0 To rst.Fields.count - 1 
                objSheet.Cells(1, iCol + 1).Value = rst.Fields(iCol).Name 
            Next 
             
             'specify cell range to recieve data
            Set rng = objSheet.Cells(2, 1) 
             'copy specified number of records to worksheet
            rng.CopyFromRecordset rst, rowsToReturn 
             'autofit columns to make data fit
            objSheet.Columns.AutoFit 
             
             'close the workbook
            wkb.SaveAs FileName:=strExcelFile '<<<Save as employee's name
            wkb.Close '<<<Close workbook because we are done with it
             
             'quit excel and release object variables
            Set objSheet = Nothing 
            Set wkb = Nothing 
            xlApp.Quit 
            Set xlApp = Nothing 
        End If 
        tblrst.MoveNext '<<<Move to next primary table field value
    Loop 
     
    MsgBox "All records exported to Excel." 
     
     'close database connection
    tblrst.Close 
    Set tblrst = Nothing 
    rst.Close 
    Set rst = Nothing 
    db.Close 
    Set db = Nothing 
     
End Sub