Public Function CLetter(v As Long) As String 
     'The If statement is just checking to see if a workbook is active. This is because this
     ' function uses the .Address method, which returns the address of a given cell.  If no
     ' workbook is active, then it creates one, gets the value, and closes it
     'Here is a breakdown of the different parts of the code
     'CODE:  Left(Cells(1, v).Address(1, 0), InStr(1, Cells(1, v).Address(1, 0), "$") - 1)
     ' Cells(1, v).Address(1, 0)         - Returns cell address in form AB$1
     ' InStr(1, celladdress, "$")        - Position of $ in cell address
     ' Left(celladdress, positionof$ -1) - Returns everything to left of $, which is col letter
    If ActiveWorkbook Is Nothing Then 
        Application.ScreenUpdating = False 
        Workbooks.Add 
        CLetter = Left(Cells(1, v).Address(1, 0), InStr(1, Cells(1, v).Address(1, 0), "$") - 1) 
        ActiveWorkbook.Close 
        Application.ScreenUpdating = True 
    Else 
        CLetter = Left(Cells(1, v).Address(1, 0), InStr(1, Cells(1, v).Address(1, 0), "$") - 1) 
    End If 
End Function 
Public Function CNumber(v As String) As Integer 
    If ActiveWorkbook Is Nothing Then 
        Application.ScreenUpdating = False 
        Workbooks.Add 
        CNumber = Range(v & "1").Column 
        ActiveWorkbook.Close 
        Application.ScreenUpdating = True 
    Else 
        CNumber = Range(v & "1").Column 
    End If 
End Function 
Sub EnterColumnLetters() 
     'Enters the column letter into row 1 on activesheet,
     ' and the corresponding number into row 2
    Dim CLL As Range 
    Range("1:2").Insert 
    Range("1:2").NumberFormat = "@" 
    For Each CLL In Rows(1).Cells 
        CLL = CLetter(CLL.Column) 
        CLL.Offset(1, 0) = CNumber(CLL.Text) 
    Next CLL 
     'Columns.AutoFit
End Sub