Option Explicit 
 
 'This one updates all the fields in the document:
Sub UpdateALL() 
    Dim oStory As Object 
    Dim oToc As Object 
     
     'exit if no document is open
    If Documents.Count = 0 Then Exit Sub 
    Application.ScreenUpdating = False 
     
    For Each oStory In ActiveDocument.StoryRanges 
        oStory.Fields.Update 'update fields in all stories
    Next oStory 
     
    For Each oToc In ActiveDocument.TablesOfContents 
        oToc.Update 'update TOC's
    Next oToc 
     
    Application.ScreenUpdating = True 
End Sub 
 
 'This is the Dirty way to do it:
Sub UpdateALL2() 
     'exit if no document is open
    If Documents.Count = 0 Then Exit Sub 
    Application.ScreenUpdating = False 
     
     'changing views updates all fields!
    With ActiveWindow.View 
        .Type = wdMasterView 
        .Type = wdPrintView 
    End With 
     
    Application.ScreenUpdating = True 
End Sub 
 
 'Update only the fields in your footer like:
Sub UpdateFooter() 
    Dim i As Integer 
     
     'exit if no document is open
    If Documents.Count = 0 Then Exit Sub 
    Application.ScreenUpdating = False 
     
     'Get page count
    i = ActiveDocument.BuiltInDocumentProperties(14) 
     
    If i >= 1 Then 'Update fields in Footer
        ActiveDocument.Sections(ActiveDocument.Sections.Count) _ 
        .Footers(1).Range.Fields.Update 
    End If 
     
    Application.ScreenUpdating = True 
End Sub 
 
 'Update only the fields in your footer like:
Sub UpdateHeader() 
    Dim i As Integer 
     
     'exit if no document is open
    If Documents.Count = 0 Then Exit Sub 
    Application.ScreenUpdating = False 
     
     'Get page count
    i = ActiveDocument.BuiltInDocumentProperties(14) 
     
    If i >= 1 Then 'Update fields in Header
        ActiveDocument.Sections(ActiveDocument.Sections.Count) _ 
        .Headers(1).Range.Fields.Update 
    End If 
     
    Application.ScreenUpdating = True 
End Sub 
 
 'In some versions of Word you have to move the selection to the section you're updating
Sub UpdateFooter2() 
    Dim i As Integer 
     
     'exit if no document is open
    If Documents.Count = 0 Then Exit Sub 
    Application.ScreenUpdating = False 
     
     'Get page count
    i = ActiveDocument.BuiltInDocumentProperties(14) 
     
    If i >= 1 Then 'Update fields in Footer
        Selection.EndKey wdStory 'move selection to end of document
         
        ActiveDocument.Sections(ActiveDocument.Sections.Count) _ 
        .Footers(1).Range.Fields.Update 
    End If 
     
    Application.ScreenUpdating = True 
End Sub