Option Explicit 
 'Api declaration for suspending operation for a specified time
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long) 
 
 
Sub GetUpdatedMessage() 
     '   Turn off screen-updating and disable the canceling the procedure
     '   while the internet connection is being made
     
    With Application 
        .ScreenUpdating = False 
        .EnableCancelKey = xlDisabled 
         
         
        On Error Goto ErrorProcedure 
         '        Opens and Excel file on the internet
        .Workbooks.Open ("http://www.jlxl.net/JLXLVersionControl.xls") 
         
         
        Dim szNewMsg As String 
         '        Checks for the value in cell A3 of the remote workbook
         '        and stores it in a variable
        szNewMsg = Range("A3").Value 
         
         
         '        Then close the workbook
        .Workbooks("JLXLVersionControl.xls").Close savechanges:=False 
         
         
        .EnableCancelKey = xlInterrupt 
        .ScreenUpdating = True 
    End With 
     
     
     '   Determine the updated string's length
    Dim lMsgLen As Long 
    lMsgLen = Len(szNewMsg) 
     
     '   Our counter variable
    Dim lCount As Long 
     
    Do 
         
        Dim i As Long 
        For i = 1 To lMsgLen * 2 
             
             '           Create a pause
            Sleep 80& 
            DoEvents 
             
             '           The rotating message
            Application.StatusBar = Mid$(Space(lMsgLen) & szNewMsg, i, lMsgLen) 
             
        Next i 
         
         '       Increment our {Do} loop counter
        lCount = lCount + 1 
         
         '   When our counter reaches 3, were done:
    Loop Until lCount = 3 
     
     '   So clear the StatusBar
    Application.StatusBar = Empty 
     
    Exit Sub 
     
ErrorProcedure: 
    MsgBox Err.Description 
    Application.ScreenUpdating = True 
    Application.EnableCancelKey = xlInterrupt 
End Sub